无法从字符串中删除"空字符"

Question

几个月前我问了一个类似的问题.感谢Rob Kennedy,我可以把我的整个文本加载到Richedit 但是我无法删除Null chars.因为我用过,我可以加载我的文本Stream.

---

现在在这段代码中:

var
  strm : TMemorystream;
  str  : UTF8string;
  ss   : TStringstream;

begin
  strm := tmemorystream.Create;

  try
    strm.LoadFromFile('C:\Text.txt');
    setstring(str,PAnsichar(strm.Memory),strm.Size);
    str := StringReplace(str, #0, '', [rfReplaceAll]);  //This line doesn't work at all
    ss  := tstringstream.Create(str);
    Richedit1.Lines.LoadFromStream(ss);
  finally
    strm.Free;
    ss.Free;
  end;
end;

我转换TMemorystream为string删除Null Chars,StringReplace()然后再将其转换TStringstream为加载它Richedit.lines.LoadFromStream.

但我的问题是我无法删除Null Character使用StringReplace().我可以替换其他角色但不能#0.

有没有办法直接删除null charcters TMemorystream并将其加载到Richedit？怎么样？如果它不可能或者它非常复杂,当我将文本转换为时,如何删除它们string？

谢谢.

Answer 1

据我所知,所有搜索/替换实用程序,无论是一次还是其他,都将输入转换为PChar,其中'#0'是终止字符.因此,他们永远不会超过第一个Null之前的字符串部分.您可能需要设计自己的机制.只是一个简单的例子:

var
  i: Integer;
begin
  Assert(str <> '');
  i := 1;
  while i <= Length(str) do
    if str[i] = #0 then
      Delete(str, i, 1)
    else
      Inc(i);

更换流将同样涉及测试每个字符,然后相应地调整流,然后在决定删除之后再继续.

Answer 2

Sertac的答案是准确的,你应该接受它.如果性能很重要,并且您有一个包含空字符常见实例的大字符串,那么您应该尝试减少堆分配的数量.以下是我将如何实现这一点:

function RemoveNull(const Input: string): string;
var
  OutputLen, Index: Integer;
  C: Char;
begin
  SetLength(Result, Length(Input));
  OutputLen := 0;
  for Index := 1 to Length(Input) do
  begin
    C := Input[Index];   
    if C <> #0 then
    begin
      inc(OutputLen);
      Result[OutputLen] := C;
    end;
  end;
  SetLength(Result, OutputLen);
end;

如果你想直接在内存流中进行,那么你可以这样做:

procedure RemoveNullFromMemoryStream(Stream: TMemoryStream);
var
  i: Integer;
  pIn, pOut: PByte;
begin
  pIn := Stream.Memory;
  pOut := pIn;
  for i := 0 to Stream.Size-1 do
  begin
    if pIn^ <> 0 then
    begin
      pOut^ := pIn^;
      inc(pOut);
    end;
    inc(pIn);
  end;
  Stream.SetSize(NativeUInt(pOut)-NativeUInt(Stream.Memory));
end;