具有运算符优先级规则的Perl 6语法示例

Question

我是Perl的新手,想要使用运算符创建一个特定于域的语言,这些运算符优先使用新的Perl 6语法功能.例如,以正确的方式解析"1 + 2*6".

我到目前为止找到的文档(例如这个)没有为具有优先级声明的运算符提供语法规则的示例.

我有这个非常简单的例子

use v6;

#use Grammar::Tracer;

grammar TestGrammar {

    token TOP {
        <digit> <infix> <digit>
    }

    token infix:sym<times> is equiv(&infix:<*>) { <sym> }

}

sub MAIN() {
    my $text = "1 times 2" ;
    say $text ;

    my $match = TestGrammar.parse($text);
    say $match;
}

这给了我

No such method 'infix' for invocant of type 'TestGrammar'

我只想构建一个抽象语法树.

Answer 1

AFAIK你不能在语法中设置中缀运算符和定义优先级等.这些仅适用于扩展Perl 6.

这是一种可能的方法.它在添加之前解析乘法项,并且还允许单词或符号,例如times或*.

use v6;

grammar TestGrammar {

    rule TOP      { <expr=.add> }

    rule add      { <expr=.multiply> +% [ <add-op> ] }
    rule multiply { <digit> +%  [ <mult-op> ] }

    proto token mult-op {*}
    token mult-op:sym<times>   { <sym>|'*' }
    token mult-op:sym<divided> { <sym>|'/' }

    proto token add-op {*}
    token add-op:sym<plus>     { <sym>|'+' }
    token add-op:sym<minus>    { <sym>|'-' }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2 * 6", "4 times 7 minus 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}

请注意,这%是分隔符运算符.<digit> +% [ <mult-op> ]指由乘法运算符分开的数字的列表(times,*,divided或/).

替代解决方案2014年9月:

S05确实提到虽然规则和标记是特殊方法,但两者都可以声明为multi并且像常规方法一样接受参数.

此方法利用递归和多分派来实现运算符优先级.

use v6;

grammar TestGrammar {

    rule TOP                { <expr(3)> }

    # operator multi-dispatch, loosest to tightest
    multi token op(3) {'+'|'-'|add|minus}
    multi token op(2) {'*'|'/'|times|divided}
    multi token op(1) {'**'}

    # expression multi-dispatch (recursive)
    multi rule expr(0)      { <digit> | '(' ~ ')' <expr(3)> }
    multi rule expr($pred)  { <expr($pred-1)> +% [ <op($pred)> ] }

}

sub MAIN() {
    for ("2+2", "2 + 2", "1 * 2", "1 + 2**3 * 6", "4 times (7 minus 3) * 3") {
        say $_;
        my $match = TestGrammar.parse($_);
        say $match;
    }
}