使{和}忽略仅包含空格的行

Question

当您使用{和}在vim中按段导航时,它会跳过除空格之外什么都没有的行,尽管它们"空白".

我如何说服vim将"仅空白"行视为段落,以便{和}将跳转到它们？

Answer 1

这是一个正确处理计数的修改版本:

function! ParagraphMove(delta, visual, count)
    normal m'
    normal |
    if a:visual
        normal gv
    endif

    if a:count == 0
        let limit = 1
    else
        let limit = a:count
    endif

    let i = 0
    while i < limit
        if a:delta > 0
            " first whitespace-only line following a non-whitespace character           
            let pos1 = search("\\S", "W")
            let pos2 = search("^\\s*$", "W")
            if pos1 == 0 || pos2 == 0
                let pos = search("\\%$", "W")
            endif
        elseif a:delta < 0
            " first whitespace-only line preceding a non-whitespace character           
            let pos1 = search("\\S", "bW")
            let pos2 = search("^\\s*$", "bW")
            if pos1 == 0 || pos2 == 0
                let pos = search("\\%^", "bW")
            endif
        endif
        let i += 1
    endwhile
    normal |
endfunction

nnoremap <silent> } :<C-U>call ParagraphMove( 1, 0, v:count)<CR>
onoremap <silent> } :<C-U>call ParagraphMove( 1, 0, v:count)<CR>
" vnoremap <silent> } :<C-U>call ParagraphMove( 1, 1)<CR>
nnoremap <silent> { :<C-U>call ParagraphMove(-1, 0, v:count)<CR>
onoremap <silent> { :<C-U>call ParagraphMove(-1, 0, v:count)<CR>
" vnoremap <silent> { :<C-U>call ParagraphMove(-1, 1)<CR>

Answer 2

{ 和 } 命令按“段落”移动，vim 的文档（请参阅 参考资料:help paragraph）说：

请注意，空行（仅包含空格）不是段落边界。

因此，唯一的方法就是重新映射 { 和 }。就像是：

nmap { ?^\\s*$<CR>
nmap } /^\\s*$<CR>

可以，但您可能需要调整它，这样它就不会改变您的搜索历史记录。