保留时间值的动态PL/SQL日期参数

Question

这可能是一个愚蠢的问题,但我找不到一个在动态调用的PL/SQL过程中传递"DATE"类型的解决方案.我需要的是在被调用的proc中传递日期和时间部分:

create or replace 
PROCEDURE DATE_TIME_TEST (  dte_Date_IN  IN DATE ) 
IS
    vch_SQL_Stmnt VARCHAR2(2000);
BEGIN
    DBMS_OUTPUT.PUT_LINE('Date is :'||TO_CHAR(dte_Date_IN, 'DD-Mon-YYYY HH24:MI:SS'));

END;
/

declare
    v_sql varchar2(2000);
begin
    v_sql := 'begin DATE_TIME_TEST( dte_Date_IN => '''|| 
              sysdate || ''''|| '); end;';
    execute immediate v_sql;
end; 
/

这里的输出是 - 日期是:2013年8月27日00:00:00.

我希望它是 - 日期是:2013年8月27日13:01:09

Answer 1

使用绑定变量

SQL> create or replace procedure proc( p_dt in date )
  2  as
  3  begin
  4    dbms_output.put_line( to_char( p_dt, 'yyyy-mm-dd hh24:mi:ss' ));
  5  end;
  6  /

Procedure created.

SQL> declare
  2    l_sql varchar2(1000);
  3  begin
  4    l_sql := 'begin proc(:dt); end;';
  5    execute immediate l_sql using sysdate;
  6  end;
  7  /
2013-08-26 22:14:26

PL/SQL procedure successfully completed.

您的代码的问题在于,为了构建您的字符串,Oracle必须将其转换DATE为a VARCHAR2.它使用你的会话来做到这一点NLS_DATE_FORMAT.但是你的会话NLS_DATE_FORMAT可能不包含时间组件,因此在实际调用过程时会丢失时间.使用绑定变量意味着您不必处理那种隐式转换(它也更有效,更安全).

如果你真的想避免使用绑定变量,可以sysdate使用a 显式地转换为字符串to_char,然后to_date在动态过程调用中放置一个.但这是很多额外的代码和一些不必要的转换.

SQL> ed
Wrote file afiedt.buf

  1  declare
  2    l_sql varchar2(1000);
  3  begin
  4    l_sql := q'{begin proc(to_date('}' ||
  5               to_char(sysdate, 'yyyy-mm-dd hh24:mi:ss') ||
  6               q'{', 'yyyy-mm-dd hh24:mi:ss')); end;}';
  7    execute immediate l_sql;
  8* end;
SQL> /
2013-08-26 22:19:52

PL/SQL procedure successfully completed.