Excel VBA按名称引用QueryTable对象

Question

我正在开发一个带有VBA的MS Excel 2013工具,它涉及使用QueryTables.我遇到的一个不便是访问Excel工作表中的现有 QueryTables.目前,我可以找到访问查询表的唯一方法是通过整数索引.我提出了以下代码,以便快速验证概念

Sub RefreshDataQuery()

Dim querySheet As Worksheet
Dim interface As Worksheet

Set querySheet = Worksheets("QTable")
Set interface = Worksheets("Interface")

Dim sh As Worksheet
Dim QT As QueryTable

Dim startTime As Double
Dim endTime As Double

Set QT = querySheet.ListObjects.item(1).QueryTable

startTime = Timer
QT.Refresh
endTime = Timer - startTime

interface.Cells(1, 1).Value = "Elapsed time to run query"
interface.Cells(1, 2).Value = endTime
interface.Cells(1, 3).Value = "Seconds"

End Sub

这有效,但我真的不想这样做.最终产品工具最多有五个不同的QueryTable.我想要的是通过名称引用QueryTable.

如果我能翻译下面的代码,那会更好

Set QT = querySheet.ListObjects.item(1).QueryTable

对于某些事情

Set QT = querySheet.ListObjects.items.QueryTable("My Query Table")

任何建议将不胜感激.

Answer 1

在Excel 2003及更早版本中,外部数据连接将创建一个QueryTable对象,其父级是工作表.您可以通过QueryTables集合对象访问QueryTable对象.与大多数集合对象一样,您可以将索引号或名称传递给(默认)Item方法以获取它.

Sheet1.QueryTables("MyQtName")

当您在新版本中打开2003工作表时,它仍然具有QueryTable对象,并且可以以相同的方式访问它.即使您转换文件格式,QueryTable仍然存在.

在2007及更高版本中,只有三种方法可以创建一个QueryTable,它将成为Worksheet.QueryTables的成员:

1. 通过代码
2. 数据 - 来自文本
3. 数据 - 来自网络

这些新版本中的所有其他UI外部数据连接将不会出现在QueryTables成员中,而是出现在ListObject中.ListObject将只有一个QueryTable对象,可以通过ListObject.QueryTable属性访问.

这是坏消息.QueryTable,其ListObject中的父级没有Name属性.好吧,它就在那里,但是如果你试图访问它,你将得到运行时错误1004.我猜MS决定因为每个ListObject只有一个QueryTable,所以它应该有一个名称没有意义.

如果您尝试将Worksheet.QueryTables.QueryTable转换为ListObject,外部数据连接将消失,新的ListObject没有QueryTable.

由于QueryTables.Count返回零,因此所有QueryTable都在ListObjects内,并且没有名称.ListObjects有名称.您可以使用

Sheet1.ListObjects("MyListName").QueryTable

这是一个函数,它接受一个名称和一个工作表,并返回一个QueryTable,该QueryTable具有该名称或者是具有该名称的ListObject的子代.

Public Function QueryTableByName(ByVal sName As String, ByRef sh As Worksheet) As QueryTable

    Dim qt As QueryTable
    Dim lo As ListObject

    On Error Resume Next
        Set qt = sh.QueryTables(sName)
    On Error GoTo 0

    If qt Is Nothing Then
        On Error Resume Next
            Set lo = sh.ListObjects(sName)
        On Error GoTo 0

        If Not lo Is Nothing Then
            On Error Resume Next
                Set qt = lo.QueryTable
            On Error GoTo 0
        End If
    End If

    Set QueryTableByName = qt

End Function

Answer 2

根据ListObject的这个MSDN链接,没有任何QueryTables属性的集合ListObjects.正确的代码是:

Set QT = querySheet.ListObjects.items(1).QueryTable

你可能需要的是引用适当的ListObject item(只是示例代码):

Dim LS as ListObject
Set LS = querySheet.ListObjects("My LO 1")
Set QT = LS.QueryTable

另一种方法是通过WorkSheet property这种方式引用QT :

Set QT = Worksheet("QTable").QueryTables("My Query Table")