在Clojure中计算GS1校验位的更惯用的方法

Question

我正在尝试计算GS1校验位,并提出以下代码.计算校验位的算法是:

1. 反转条形码
2. 丢弃最后一位数(计算的校验位)
3. 将数字加上第一,第三,第五等数字乘以3,偶数数加1.
4. 从最接近的十倍或更高的倍数中减去总和

这听起来很简单,但我提出的解决方案似乎有点不雅.它确实有效,但我想知道是否有更优雅的方式来写这个.

(defn abs "(abs n) is the absolute value of n" [n]
  (cond
   (not (number? n)) (throw (IllegalArgumentException.
                 "abs requires a number"))
   (neg? n) (- n)
   :else n))

(defn sum-seq "adds (first number times 3) with (second number)"
  [coll]
  (+ 
   (* (first coll) 3)
   (second coll)))

(defn sum-digit
  [s]
  (reduce +
  (map sum-seq
  (partition 2 2 '(0) 
  (map #(Integer/parseInt %)
  (drop 2 (clojure.string/split (clojure.string/reverse s) #"")))))))

(defn mod-higher10 "Subtracts the sum from nearest equal or higher multiple of ten"
  [i]
  (if (zero? (rem i 10))
    0
    (- 10(rem i 10))))

(defn check-digit "calculates a GS1 check digit"
  [s]
  (mod-higher10 
   (sum-digit s)))

(= (check-digit "7311518182472") 2)
(= (check-digit "7311518152284") 4)
(= (check-digit "7311518225261") 1)
(= (check-digit "7311518241452") 2)
(= (check-digit "7311518034399") 9)
(= (check-digit "7311518005955") 5)
(= (check-digit "7311518263393") 3)
(= (check-digit "7311518240943") 3)
(= (check-digit "00000012345687") 7)
(= (check-digit "012345670") 0)

Answer 1

(defn check-digit 
  [s] 
  (let [digits        (map #(Integer/parseInt (str %)) s)
        [chk & body]  (reverse digits)
        sum           (apply + (map * body (cycle [3 1])))
        moddiff       (mod (- 10 sum) 10)]
       moddiff))  

这个实现使用我意识到的两个clojure习语:

• let 管理本地分解(和重用)
• map 第二个集合,是一个与问题"相邻"的无限懒惰序列.

还解构列表,以便将检查谓词编写为(= moddiff chk).