如何在Delphi中使用Default(T)测试泛型类型变量是否相等？

Question

我正在尝试编写如下所示的通用缓存属性访问器,但在尝试检查存储变量是否已包含值时遇到编译器错误:

function TMyClass.GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
begin
  if ADataValue = Default(T) then // <-- compiler error on this line
    ADataValue := ARetriever();
  Result := ADataValue;
end;

我得到的错误是"E2015运算符不适用于此操作数类型".

我是否必须约束T才能使这项工作？帮助文件说Default()除了泛型类型之外会接受任何东西.在我的情况,我用简单的类型,如内容大都String,Integer和TDateTime.

或者是否有其他库函数来执行此特定检查？

我正在使用Delphi 2009以防万一.

---

PS:以防万一我从代码中不清楚我正在尝试做什么:在我的情况下,由于各种原因确定实际属性值可能需要一段时间,有时甚至根本不需要它们.在正面但是值是常量所以我只想调用第一次访问属性时确定实际值的代码,然后将值存储在类字段中,下次访问该属性时返回缓存值直.这是我希望能够使用该代码的示例:

type
  TMyClass = class
  private
    FSomeProp: String;
    function GetSomeProp: String;

    function GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
  public
    property SomeProp read GetSomeProp;
  end;

function GetSomeProp: String;
begin
  Result := GetProp<String>(FSomeProp,
                            function: String
                            begin
                              Result := SomeSlowOrExpensiveCalculation;
                            end);
end;

(显然,这不仅仅是一个属性)

Answer 1

在对Binis的评论中提示并在Generics.Collections中稍微挖掘一下后,我想出了以下内容,它看起来像我想要的那样工作:

function TMyClass.GetProp<T>(var ADataValue: T; const ARetriever: TFunc<T>): T;
var
  lComparer: IEqualityComparer<T>;
begin
  lComparer := TEqualityComparer<T>.Default;
  if lComparer.Equals(ADataValue, Default(T)) then
    ADataValue := ARetriever();
  Result := ADataValue;
end;