如何在三列中拆分Oracle中的varchar列

Question

我有一个可以容纳120个字符的地址字段,需要将它分成三个不同的列,每个字符长40个字符.

例:

Table name: Address 
Column name: Street_Address
Select Street_Address  * from Address

输出: 123 Main St North Pole Factory 44, near the rear entrance cross the street and turn left and keep walking straight.

我需要将此地址拆分为address_1 address_2 和address_3.

所有三个地址都是varchar(40)数据类型.

所以结果应该是这样的:

Address_1
152 Main st North Pole Factory 44, near 

Address_2
the rear entrance cross the street and

Address_3
turn left and keep walking straight.

请注意,每个地址字段最多可以包含40个字符,并且必须是整个字,它不能被截断一半而且没有意义.

我正在使用oracle 11i数据库.

Answer 1

这相当“快速而肮脏”，但我认为它给出了正确的结果。
我使用了管道表，但可能没有它也可以完成......

这是一个 sqlfiddle 演示

create table t1(id number, adr varchar2(120))
/
insert into t1 values(1, '152 Main st North Pole Factory 44, near the rear entrance cross the street and turn left and keep walking straight.')
/
insert into t1 values(2, '122 Main st Pole Factory 44, near the rear entrance cross the street and turn left and keep walking straight. asdsa')
/

create or replace type t is object(id number, phrase1 varchar2(40), phrase2 varchar2(40), phrase3 varchar2(40))
/
create or replace type t_tab as table of t
/

create or replace function split_string(id number, str in varchar2) return t_tab
  pipelined is

  v_token   varchar2(40);
  v_token_i number := 0;
  v_cur_len number := 0;
  v_res_str varchar2(121) := str || ' ';
  v_p1      varchar2(40);
  v_p2      varchar2(40);
  v_p3      varchar2(40);
  v_p_i     number := 1;

begin

  v_token_i := instr(v_res_str, ' ');

  while v_token_i > 0 loop

    v_token := substr(v_res_str, 1, v_token_i - 1);

      if v_cur_len + length(v_token) < 40 then

        if v_p_i = 1 then 
          v_p1 := v_p1 || ' ' || v_token;
        elsif v_p_i = 2 then 
          v_p2 := v_p2 || ' ' || v_token;
        elsif v_p_i = 3 then 
          v_p3 := v_p3 || ' ' || v_token;
        end if;

        v_cur_len := v_cur_len + length(v_token) +1;
     else
        v_p_i := v_p_i + 1;

        if v_p_i = 2 then 
          v_p2 := v_p2 || ' ' || v_token;
        elsif v_p_i = 3 then 
          v_p3 := v_p3 || ' ' || v_token;
        end if;

        v_cur_len := length(v_token);

     end if;

     v_res_str := substr(v_res_str, v_token_i + 1);
     v_token_i := instr(v_res_str, ' ');

   end loop;

   pipe row(t(id, v_p1, v_p2, v_p3));
   return;
end split_string;
/

和查询：

select parts.*, length(PHRASE1), length(PHRASE2), length(PHRASE3)
from t1, table(split_string(t1.id, t1.adr)) parts