在Grails中使用AOP不适用于服务

Question

我使用Grails 2.2.3并在grails-app/conf/spring/resources.groovy中输入以下代码

beans = {
    xmlns aop:"http://www.springframework.org/schema/aop"
    loggerAspect(com.test.aop.aspect.LoggerAspect)
    aop{
        config("proxy-target-class": true) {
            aspect(id: "beforeService", ref: "loggerAspect") {
                before method: "beforeMethod", 
                pointcut: "execution(* com.test.DemoService.serviceMethod())"
            }
            aspect(id: "afterService", ref: "loggerAspect") {
                after method: "afterMethod", 
                pointcut: "execution(* com.test.DemoService.serviceMethod())"
            }
        }
    }
}

然后,在src/groovy/com/test/aop/aspect下创建一个方面类

package com.test.aop.aspect
class LoggerAspect {
    def beforeMethod(JoinPoint jp){
        println '-- Before Method.'
    }

    def afterMethod(JoinPoint jp){
        println '-- After Method.'
    }
}

并在grails-app/services/com/test下创建一个服务类

package com.test
class DemoService {
    def serviceMethod() {
        println 'In DemoService.serviceMethod()'
    }
}

并创建一个控制器来调用服务进行测试

package com.test
class DemoController {
    def index() {
        println 'In DemoController.index()'
        def demoService = new DemoService()
        demoService.serviceMethod()

         render 'Hello World'
    }
}

最后,我通过url测试aop:

http://myhost:8080/grails-spring-aop/demo/index

并且没有调用aop.以下是结果:

| Server running. Browse to http://myhost:8080/grails-spring-aop/
In DemoController.index()
In DemoService.serviceMethod()

我将以下行添加到服务类:

static transactional = false

而且,它仍然不适合我.

任何人都知道如何解决这个问题或者这是不可能的.或者我做错了什么.

谢谢.

Answer 1

您需要在控制器中注入服务(spring bean),而不是创建它的实例.

package com.test
class DemoController {
    def demoService //Autowired, not required to specify in resources.groovy

    def index() {
        println 'In DemoController.index()'
        demoService.serviceMethod()

        render 'Hello World'
    }
}

此外,该方面可以基于以下内容进行注释:

package com.test.aop.aspect

@Aspect
class LoggerAspect {

    //A more generic advice would be as below
    //@Before("execution(* com.test.*.*(..))")
    @Before("com.test.DemoService.serviceMethod()")
    def beforeMethod(){
        println '-- Before Method.'
    }

    //A more generic advice would be as below
    //@Around("execution(* com.test.*.*(..))")
    @After("com.test.DemoService.serviceMethod()")
    def afterMethod(){
        println '-- After Method.'
    }
}

而resources.groovy可能会成为:

beans = {
    loggerAspect(com.test.aop.aspect.LoggerAspect)

    xmlns aop:"http://www.springframework.org/schema/aop"
    aop{
        config("proxy-target-class": true) {
            aspect(id: "loggerAspectService", ref: "loggerAspect") 
        }
    }
}