在组织模式下完全隐藏:PROPERTIES:抽屉

Question

有人可以给我一些帮助,以完全隐藏:PROPERTIES:抽屉,包括说明的线:PROPERTIES:.

* TASKS (with deadines)

    ** Next Action [#A] Ask the geniuses how to do this.  :lawlist:
       DEADLINE: <2013-07-04 Thu >
         :PROPERTIES:
         :ToodledoID: 330686790
         :ToodledoFolder: TASKS
         :Hash:     afa88f17317bbe2ce0ce661333cdcfb4
         :END:
       This line is for notes, which appears underneath the properties drawer.

* UNDATED (without deadlines)

    ** Someday [#A] Close but no cigar -- keep trying.  :lawlist:
          :PROPERTIES:
          :ToodledoID: 330686680
          :ToodledoFolder: TASKS
          :Hash:     eb0b8d360b5b1453dd66ed0c5698e135
          :END:
       This line is for notes, which appears underneath the properties drawer.

我没有通过谷歌搜索看到这个功能,所以我猜测需要一些特殊的代码行才能使这个功能请求成为现实.[换句话说,我不认为这是一个超级用户的问题,因为这需要用一些特殊的代码来发明.]

Answer 1

以下的答案必须完全隐藏一切:PROPERTIES:通过:END:.它可以通过评估(org-cycle-hide-drawers 'children),或(org-cycle-hide-drawers 'all)结合与轮廓视图循环相关的其他功能来进行测试.展开的标准功能包括在org-mode家庭中所有工作 - 例如show-all; org-show-subtree; 等等

(require 'org)

(defun org-cycle-hide-drawers (state)
  "Re-hide all drawers after a visibility state change."
  (when (and (derived-mode-p 'org-mode)
             (not (memq state '(overview folded contents))))
    (save-excursion
      (let* ((globalp (memq state '(contents all)))
             (beg (if globalp
                    (point-min)
                    (point)))
             (end (if globalp
                    (point-max)
                    (if (eq state 'children)
                      (save-excursion
                        (outline-next-heading)
                        (point))
                      (org-end-of-subtree t)))))
        (goto-char beg)
        (while (re-search-forward org-drawer-regexp end t)
          (save-excursion
            (beginning-of-line 1)
            (when (looking-at org-drawer-regexp)
              (let* ((start (1- (match-beginning 0)))
                     (limit
                       (save-excursion
                         (outline-next-heading)
                           (point)))
                     (msg (format
                            (concat
                              "org-cycle-hide-drawers:  "
                              "`:END:`"
                              " line missing at position %s")
                            (1+ start))))
                (if (re-search-forward "^[ \t]*:END:" limit t)
                  (outline-flag-region start (point-at-eol) t)
                  (user-error msg))))))))))

对于任何对所有各种视图之间的标签循环感兴趣的人(包括显示:PROPERTIES:抽屉内部的内容,可以org-cycle-internal-local通过添加附加条件进行简单的修改 (t ;; Default action: hide the subtree. . . .

((eq org-cycle-subtree-status 'subtree)
  (org-show-subtree)
  (org-unlogged-message "ALL")
  (setq org-cycle-subtree-status 'all))

截图 - 隐藏的抽屉:

https://www.lawlist.com/images/org_mode_properties_a.png

截图 - 抽屉可见:

https://www.lawlist.com/images/org_mode_properties_b.png