在批处理脚本中打印第二个令牌后的所有令牌

Question

我正在寻找一种更清洁的方法来做到这一点.我很确定它是错的,即使它有点有用.基本上我从文件(temp.txt)中获取这样的输出:

    Host Name:                 IBM-3J93A46MRS5
    OS Name:                   Microsoft Windows 7 Professional 
    OS Version:                6.1.7631 Service Pack 1 Build 7601
    OS Configuration:          Standalone Workstation
    Registered Owner:          IAMADMIN
    Original Install Date:     2011-12-15, 10:56:07 AM
    System Boot Time:          2013-05-27, 9:55:36 AM
    System Manufacturer:       DELL
    System Model:              4009BF7
    Time Zone:                 (UTC-05:00) Eastern Time (US & Canada)
    Total Physical Memory:     16,316 MB
    Available Physical Memory: 11,356 MB

并尝试将第二列数据放入变量中.取决于我是否想要它.我正在使用Findstr来清除它.

    @echo off
    setlocal enabledelayedexpansion

    systeminfo > temp.txt
    set "tmp_result_file=temp.txt"

    for /f "tokens=3-7 delims= " %%i in ('FINDSTR /C:"OS Name:" %tmp_result_file%') do set "OSNAME=%%i %%j %%k %%l"
    for /f "tokens=3-10 delims= " %%i in ('FINDSTR /V /C:"BIOS Version:" %tmp_result_file%^|FIND /I "OS Version:"') do set "OSVER=%%i %%j %%k %%l %%m %%n %%o %%p"
    for /f "tokens=4-7 delims= " %%i in ('FINDSTR /C:"Original Install Date:" %tmp_result_file%') do set "INSTDATE=%%i %%j %%k %%l"
    for /f "tokens=3-7 delims= " %%i in ('FINDSTR /C:"System Manufacturer:" %tmp_result_file%') do set "SYSMFG=%%i %%j %%k %%l"
    for /f "tokens=3-7 delims= " %%i in ('FINDSTR /C:"System Model:" %tmp_result_file%') do   set "SYSMDL=%%i %%j %%k %%l"

    echo.
    echo Operating System      : %OSNAME% , %OSVER% 
    echo Original Install Date : %INSTDATE%
    echo Model Information     : %SYSMFG% %SYSMDL% 

我不喜欢我如此准确地使用令牌,我只需要搜索值之后的所有内容.

Answer 1

走简单的路 :-)

@echo OFF &setlocal
FOR /f "tokens=1*delims=:" %%i IN (file) DO (
    FOR /f "tokens=*" %%a IN ("%%j") DO SET "$%%i=%%a"
)
SET "$"
echo Windows version: %$OS Name%

..输出是：

$可用物理内存=11,356 MB
$主机名=IBM-3J93A46MRS5
$原始安装日期=2011-12-15, 10:56:07 AM
$OS 配置=独立工作站
$OS 名称=Microsoft Windows 7 Professional
$OS 版本=6.1.7631 Service Pack 1 Build 7601
$注册所有者= IAMADMIN
$系统启动时间=2013-05-27, 9:55:36 AM
$系统制造商=戴尔
$系统型号=4009BF7
$Time Zone=(UTC-05:00) 东部时间（美国和加拿大）
$总物理内存=16,316 MB
Windows 版本：Microsoft Windows 7 Professional

Answer 2

不需要延迟扩展,临时文件或FINDSTR,当然也不需要计算以空格分隔的标记.您只需设置正确的DELIMS和TOKENS选项即可.第一个FOR/F处理输出systeminfo并将每行解析为名称和值.第二个FOR/F从每个值中去除前导空格.剩下的就是一系列IF语句来测试每个名称并根据需要设置所需的变量.

@echo off
setlocal

for /f "delims=: tokens=1*" %%A in ('systeminfo') do (
  for /f "tokens=*" %%S in ("%%B") do (
    if "%%A"=="OS Name" set "OSNAME=%%S"
    if "%%A"=="OS Version" set "OSVER=%%S"
    if "%%A"=="Original Install Date" set "INSTDATE=%%S"
    if "%%A"=="System Manufacturer" set "SYSMFG=%%S"
    if "%%A"=="System Model" set "SYSMDL=%%S"
  )
)

echo(
echo Operating System      : %OSNAME%, %OSVER%
echo Original Install Date : %INSTDATE%
echo Model Information     : %SYSMFG% %SYSMDL%

如果要捕获更多值,可能需要指定搜索字符串:使用字符串的变量名称对,并添加一些额外的FOR循环来处理每个测试,如下所示:

@echo off
setlocal

for /f "delims=: tokens=1*" %%A in ('systeminfo') do for %%S in (
  "OS Name:OSNAME"
  "OS Version:OSVER"
  "Original Install Date:INSTDATE"
  "System Manufacturer:SYSMFG"
  "System Model:SYSMDL"
) do for /f "delims=: tokens=1*" %%a in ("%%~S") do if %%A==%%a (
  for /f "tokens=*" %%s in ("%%B") do set "%%b=%%s"
)

echo(
echo Operating System      : %OSNAME%, %OSVER%
echo Original Install Date : %INSTDATE%
echo Model Information     : %SYSMFG% %SYSMDL%