PL / SQL过程的同步。如何保证一次只执行一个程序？

Question

某些PL / SQL过程需要花费大量时间进行评估（因为重新计算和更新了大量数据）。

我想将执行此过程的执行上下文数量限制为单个。

如果执行其他上下文，则什么也不做...

但是我不知道在PL / SQL代码中使用哪些原子操作。

注意：恐怕如果服务器在过程评估的中间暂停时，使用表行进行同步会导致DB中的状态不一致...

Answer 1

您可以DBMS_LOCK.request用来生成唯一的锁句柄。只有一个会话可以同时持有此锁。如果数据库的会话重新启动意外结束，则锁将自动释放。

您可以在请求锁定时决定是否在两次提交之间都持有该锁定。

这是一个例子：

SQL> CREATE OR REPLACE PROCEDURE serial IS
  2     l_lock_handle  VARCHAR2(128 BYTE);
  3     l_lock_request INTEGER;
  4  BEGIN
  5     dbms_lock.allocate_unique(lockname => 'MY_SERIAL_PROC',
  6                               lockhandle => l_lock_handle);
  7     l_lock_request := dbms_lock.request(lockhandle => l_lock_handle,
  8                                         timeout => 5,
  9                                         release_on_commit => FALSE);
 10     CASE l_lock_request
 11        WHEN 0 THEN
 12           NULL; -- success
 13        WHEN 1 THEN
 14           raise_application_error(-20002, 'lock already reserved');
 15        ELSE
 16           raise_application_error(-20001, 'Lock error: ' || l_lock_request);
 17     END CASE;
 18     BEGIN
 19        ---------- serialized block of code           ----------
 20        ---------- (lock will be kept accross commit) ----------
 21        dbms_lock.sleep(30);
 22        ---------- End of serialized code             ----------
 23     EXCEPTION
 24        WHEN OTHERS THEN -- release lock in case of uncatched error
 25           l_lock_request := dbms_lock.release(lockhandle => l_lock_handle);
 26           RAISE;
 27     END;
 28     l_lock_request := dbms_lock.release(lockhandle => l_lock_handle);
 29  END;
 30  /

Procedure created

我将同时运行两个会话：

Session A> exec serial;                

                                       Session B> -- Before session A ends
                                       Session B> exec serial;

                                       ERROR at line 1:
                                       ORA-20002: lock already reserved
                                       ORA-06512: at "APPS.SERIAL", line 13
                                       ORA-06512: at line 1


PL/SQL procedure successfully completed

                                       Session B> -- After session A ends
                                       Session B> exec serial;

                                       PL/SQL procedure successfully completed.