如何在存储过程中创建索引？

Question

如何在存储过程中创建索引？它抱怨

消息102,级别15,状态1,过程createIndexModifiedOn,第12行
'PRIMARY'附近的语法不正确.

但是,ON [PRIMARY]如果您创建新索引并选择,SQL Server本身就会使用它Script As New Query.

如果我删除ON [PRIMARY]然后它给出了这个错误

消息102,级别15,状态1,过程createIndexModifiedOn,第12行
')'附近的语法不正确.

这是程序:

create proc [dbo].createIndexModifiedOn
    @table char(256)
as begin
    declare @idx char(256)
    set @idx = 'idx_' + SUBSTRING(@table, 7, len(@table)-1) + '_modified_on';
    IF  EXISTS (SELECT * FROM sys.indexes WHERE object_id = OBJECT_ID(@table) AND name = @idx)
        DROP INDEX [@idx] ON [@table]

    CREATE NONCLUSTERED INDEX [@idx] ON [@table]
    (
        [modified_on] ASC
    ) ON [PRIMARY]
go

这最终成为完整的查询:

create proc [dbo].createIndexModifiedOn
    @table varchar(256)
as 
    declare @idx varchar(256);
    declare @sql nvarchar(999);
    set @idx = 'idx_' + SUBSTRING(@table, 8, len(@table)-8) + '_modified_on';
    set @sql = '
    IF  EXISTS (SELECT * FROM sys.indexes WHERE object_id = OBJECT_ID(''' + @table + ''') AND name = ''' + @idx + ''')
        DROP INDEX [' + @idx + '] ON ' + @table + '

    CREATE NONCLUSTERED INDEX [' + @idx + '] ON ' + @table + '
    (
        [modified_on] ASC
    ) ON [PRIMARY] 
    ';
    print @table + ', ' + @idx;
    BEGIN TRY
        EXEC sp_executesql @sql;
    END TRY
    BEGIN CATCH
        PRINT 'errno: ' + ltrim(str(error_number()))
        PRINT 'errmsg: ' + error_message()
    END CATCH
GO

EXEC sp_MSforeachtable 'exec createIndexModifiedOn "?"'

Answer 1

您不能像以前那样在 CREATE INDEX 语句中使用变量。为此，您需要生成一个 SQL 字符串并使用sp_executesql.

手绘示例：

DECLARE @sql NVARCHAR(1024);
SET @sql = 'CREATE NONCLUSTERED INDEX [' + @idx + '] ON [' + @table + ']
(
    [modified_on] ASC
) ON [PRIMARY];';
EXEC sp_executesql @sql;