ARC(iOS)下的Delphi TThread尚未发布

Question

在ARC管理下使用Delphi for iOS终止线程的正确方法是什么？

举个简单的例子:

  TMyThread = class(TThread)
  protected
    procedure Execute; override;
  public
    destructor Destroy; override;
  end;

  TForm2 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    FThread: TMyThread;
  public
  end;

{ TMyThread }
destructor TMyThread.Destroy;
begin

  ShowMessage('Destroy');

  inherited Destroy;

end;

procedure TMyThread.Execute;
begin

  Sleep(5000);

end;

{ TForm2 }
procedure TForm2.Button1Click(Sender: TObject);
begin
  FThread := TMyThread.Create(TRUE);
  FThread.FreeOnTerminate := TRUE;
  FThread.Start;
end;

procedure TForm2.Button2Click(Sender: TObject);
begin
  ShowMessage(FThread.RefCount.ToString);
end;

procedure TForm2.Button3Click(Sender: TObject);
begin
  FThread := nil;
end;

好吧,按下Button1会产生一个线程.线程启动后,如果单击Button2,它将显示RefCount值3!好吧,1是我的FThread变量的引用,并且TThread内部创建了2个额外的引用...我已经深入研究了源代码并发现RefCount在这里增加了:

constructor TThread.Create(CreateSuspended: Boolean);

  ErrCode := BeginThread(nil, @ThreadProc, Pointer(Self), FThreadID);
  if ErrCode <> 0 then
    raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(ErrCode)]);
  {$ENDIF POSIX}

和这里:

function ThreadProc(Thread: TThread): Integer;
var
  FreeThread: Boolean;
begin
  TThread.FCurrentThread := Thread;

好吧......线程完成后(在我的情况下,5秒后),RefCount将减少到2(因为我已将FreeOnTerminate设置为TRUE,但如果我没有将FreeOnTerminate设置为TRUE,则RefCount仍为3 ).

看到问题？线程永远不会完成,并且永远不会调用析构函数,如果我调用FThread := nil,那么,RefCount应该从2减少到1(或者从3减少到2 FreeOnTerminate = FALSE),并且线程永远不会在ARC下释放...

也许我错过了一些东西,因为我习惯于没有ARC的线程......所以,我在这里缺少什么？或者在ARC下的TThread实现中是否存在错误？

也许这个TThread的定义

private class threadvar
  FCurrentThread: TThread;

应该是这样的

private class threadvar
  [Weak] FCurrentThread: TThread;

Answer 1

经过对 qc 的深入研究后，出现了以下问题和解决方法：

线程参数应传递为const

function ThreadProc(Thread: TThread): Integer;  <<-- pass_by_reference pushes
var                                                  up the ref_count.
  FreeThread: Boolean;
begin
  TThread.FCurrentThread := Thread;

如果您传递它，因为constref_count 不会达到 3。通常这不是问题，因为 ref_count 在函数退出时会减少，但在这里：

函数 Epilog 永远不会被执行，因为 pthread_exit() 会跳出代码。

但这只是解决方案的一部分，还有很多工作要做......

Dave Nottage 的完整解决方法

经过多次摆弄后，我想出了这个潜在的解决方法：

将这些 mods 添加到 Classes 单元： 更改：

function ThreadProc(Thread: TThread): Integer;

到：

function ThreadProc(const Thread: TThread): Integer;

并添加：

TThread.FCurrentThread := nil;

在这一行之后：

if FreeThread then Thread.Free;

DoTerminate在 TThread 后代中重写，因此：

procedure TMyThread.DoTerminate;
begin
  try
    inherited;
  finally
    __ObjRelease;
  end;
end;

这样调用线程：

FMyThread.Free; // This will do nothing the first time around, since the reference will be nil
FMyThread := TMyThread.Create(True);
// DO NOT SET FreeOnTerminate
FMyThread.OnTerminate := ThreadTerminate;
FMyThread.Resume;

这（至少对我来说，在设备上）会导致线程在后续调用中被销毁。

注意：在 ARC 条件下，永远不要在本地声明对线程的引用，因为当它超出范围时，线程将被销毁，并且永远不会调用 Execute 方法，更不用说它导致的其他问题。