XSLT定义一个变量并检查它是否存在

Question

我正在尝试转换XML文档.首先,我定义了一个全局变量:

 <xsl:variable name="foo"><xsl:value-of select="bar"/></xsl:variable>

现在,我正在转换的XML有可能<bar>some data</bar>定义了.它也有可能没有定义.

一旦我在下面声明了全局变量,我正在尝试输出以下内容(如果已定义):

<foo>DEFINED</foo>

如果没有定义:

<foo>NOT DEFINED</foo>

我在用 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

解决这个问题的最佳方法是什么？

Answer 1

由于您使用的是XSLT 1.0,因此您可以使用string()它进行测试.

这是一个示例样式表:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar"/>
        <results>
            <xsl:choose>
                <xsl:when test="string($foo)">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

请注意,空白区域已折叠,因此<bar> </bar>将返回false.此外,string()在直接测试元素而不是变量时也可以.

这是一些输入/输出示例:

输入

<test>
    <bar/>
</test>

要么

<test>
    <bar></bar>
</test>

要么

<test>
    <bar>    </bar>
</test>

产量

<foo>NOT DEFINED</foo>

输入

<test>
    <bar>x</bar>
</test>

产量

<foo>DEFINED</foo>

如果您可以使用XSLT 2.0,则可以将变量声明为an,xs:string并在test(test="$foo")中使用变量名称.

例:

<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar" as="xs:string"/>
        <results>
            <xsl:choose>
                <xsl:when test="$foo">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>