如何使样本运行Open CV

Question

我想使模板匹配开放CV工程样品解释这里.我到目前为止所做的步骤包括:

在我的项目中下载和导入的Open CV框架将.m扩展文件更改为.mm,在.pch文件中我已经包含了代码

 #ifdef __cplusplus
 #import <opencv2/opencv.hpp>
 #endif

 #ifdef __OBJC__
 #import <UIKit/UIKit.h>
 #import <Foundation/Foundation.h>
 #endif

我还从链接下载并导入了MatchTemplate_Demo.cpp文件.但这里有图书馆链接问题

 ld: warning: directory not found for option '-L/Users/G1/Desktop/Xcode'
   ld: warning: directory not found for option '-Lprojects/FirstOpenCv/opencv/lib/debug'
   ld: library not found for -lopencv_calib3d
   clang: error: linker command failed with exit code 1 (use -v to see invocation)

我按照同样的步骤来包含这里给出的库.

2) Add $(SRCROOT)/opencv to header search path and $(SRCROOT)/opencv/lib/debug for library search path for debug configuration and $(SRCROOT)/opencv/lib/release for release build.

3) Add OpenCV libs to linker input by modifying "Other Linker Flags" option with "-lopencv_calib3d -lzlib -lopencv_contrib -lopencv_legacy -lopencv_features2d -lopencv_imgproc -lopencv_video -lopencv_core".

现在可以请任何人告诉我应该如何让项目运行.我已经获取了源和模板图像并在项目中导入.

我基本上有ViewController.h和ViewController.mm文件,现在我不知道我应该在这些文件中编写什么来查看结果.

第2步:我需要使用相机视图实时扫描图像(这样当我将相机放在源图像上时,它应该扫描并找到模板).

在此链接上,我在导入.cpp 文件时出现链接器错误:

ld: 1 duplicate symbol for architecture i386 clang:
error: linker command failed with exit    code 1 (use -v to see invocation) 

任何人都可以建议我如何实施它.

Answer 1

你有三个相互关联的问题:

1 /如何让openCV框架在iOS项目中运行
2 /如何获取模板匹配c ++示例代码在iOS项目中运行
3 /如何与摄像机视图进行实时模板匹配

1 /如何让openCV框架在iOS项目中运行

• 如您所述,下载并导入openCV框架
• 如您所述更改.pch文件

• 检查目标构建设置中的c ++标准库是否设置为libc ++(这是新项目的默认值)

• 不要只是导入demo.cpp而不进行如下所述的更改(它是一个'原始'的c ++程序,它有自己的main功能,需要改变才能作为iOS/Cocoa项目的一部分工作).

• 不要乱用标题搜索路径,其他链接器标志等,如果您从openCV.org导入了预构建的框架,则不需要这样做.

• 除非您知道需要,否则请勿将.m文件更改为.mm.我的建议是尽可能地将c ++代码与目标C代码分开,因此大多数文件应该是.m文件(objective-C)或.cpp文件(c ++).你只需要.mm前缀用于"objective-C++",你打算在同一个文件中混合使用Objective-C和c ++.

2 /如何使模板匹配c ++示例代码在iOS项目中运行

我们将对此进行设置,以便您的iOS viewController(以及大部分iOS代码)不需要知道使用openCV/C++处理图像,同样C++代码也不需要知道它的输入位置或输出图像数据被路由到.我们通过在两者之间创建一个小的包装类来实现这一点,它将Objective-C方法调用转换为c ++类成员函数并返回.我们还将在UIImage上设置一个类别,将图像格式从iOS友好的UIImage转换为openCV-native cv :: Mat.

UIImage + OpenCV类别

你需要一些实用工具方法来从UIImage转换为cv :: Mat并返回.放置这些的好地方是UIImage类别.在XCode中:文件>新文件> Cocoa Touch> Objective-C类别将为您设置.调用类别OpenCV并使其成为UIImage的类别.这个.m文件你需要更改为.mm,因为它需要从openCV框架中理解c ++类型.

标题应如下所示:

#import <UIKit/UIKit.h>

@interface UIImage (OpenCV)

    //cv::Mat to UIImage
+ (UIImage *)imageWithCVMat:(const cv::Mat&)cvMat;

    //UIImage to cv::Mat
- (cv::Mat)cvMat;

@end

.mm文件应该通过密切关注这个适用于类别方法的openCV.org代码示例来实现这些方法(例如,您不将UIImage传递给实例方法,而是使用它来引用它self).

您可以使用类别方法,就像它们是UIImage类和实例方法一样:

UIImage* image = [UIImage imageWithCVMat:matImage];  //class method

cv::Mat matImage = [image cvMat];  //instance method

openCV包装类

创建一个包装类,将Objective-C方法(从viewController调用)转换为c ++函数

标题是这样的

//  CVWrapper.h
#import <Foundation/Foundation.h>

@interface CVWrapper : NSObject

+ (NSImage*) templateMatchImage:(UIImage*)image
                          patch:(UIImage*)patch
                         method:(int)method;
@end

我们发送模板图像,补丁图像和模板匹配方法,并返回显示匹配的图像

实现(.mm文件)

//  CVWrapper.mm
#import "CVWrapper.h"
#import "CVTemplateMatch.h"
#import "UIImage+OpenCV.h"

@implementation CVWrapper


+ (UIImage*) templateMatchImage:(UIImage *)image
                          patch:(UIImage *)patch
                         method:(int)method
{
    cv::Mat imageMat = [image cvMat];
    cv::Mat patchMat = [patch cvMat];

    cv::Mat matchImage = 
           CVTemplateMatch::matchImage(imageMat, 
                                        patchMat,
                                        method);

    UIImage* result =  [UIImage imageWithCVMat:matchImage];
    return result;
}

我们正在有效地采用标准的Objective-C方法和UIImage类型,并将它们转换为使用c ++(openCV框架)类型调用C++成员函数,并将结果转换回UIImage.

C++ TemplateMatch类

标题:

//  TemplateMatch.h

#ifndef __CVOpenTemplate__CVTemplateMatch__
#define __CVOpenTemplate__CVTemplateMatch__

class CVTemplateMatch
{
public:
    static cv::Mat matchImage (cv::Mat imageMat,
                               cv::Mat patchMat, 
                               int method);
};

#endif /* defined(__CVOpenTemplate__CVTemplateMatch__) */


@end

执行:

这是Template Match openCV示例代码,作为类实现重新编写:

//  TemplateMatch.cpp
/*
 Alterations for use in iOS project
 [1] remove GUI code (iOS supplies the GUI)
 [2] change main{} to static member function 
     with appropriate inputs and return value
 [3] change MatchingMethod{} signature 
     to return Mat value
 */

#include "CVTemplateMatch.h"

    //[1] #include "opencv2/highgui/highgui.hpp"
#include "opencv2/imgproc/imgproc.hpp"
#include <iostream>
#include <stdio.h>

using namespace std;
using namespace cv;

    /// Global Variables
Mat img; Mat templ; Mat result;
    //[1] char* image_window = "Source Image";
    //[1] char* result_window = "Result window";

int match_method; 
    //[1]  int max_Trackbar = 5; 

    /// Function Headers
Mat MatchingMethod( int, void* );  //[3] (added return value to function)

    // [2] /** @function main */
    // [2] int main( int argc, char** argv )

Mat CVTemplateMatch::matchImage (Mat image,Mat patch, int method)
    // [2]
{
        /// Load image and template
        //[2]  img = imread( argv[1], 1 );
        //[2] templ = imread( argv[2], 1 );

    img = image;           //[2]
    templ = patch;         //[2]
    match_method = method; //[2]

        /// Create windows
        //[1] namedWindow( image_window, CV_WINDOW_AUTOSIZE );
        //[1] namedWindow( result_window, CV_WINDOW_AUTOSIZE );

        /// Create Trackbar
        //[1] char* trackbar_label = "Method: \n 0: SQDIFF \n 1: SQDIFF NORMED \n 2: TM CCORR \n 3: TM CCORR NORMED \n 4: TM COEFF \n 5: TM COEFF NORMED";
        //[1] createTrackbar( trackbar_label, image_window, &match_method, max_Trackbar, MatchingMethod );

    Mat result = MatchingMethod( 0, 0 );

        //[1] waitKey(0);
        //[2] return 0;
    return result;  //[2]
}


    //[3] void MatchingMethod( int, void* )
Mat MatchingMethod( int, void* )

{
        /// Source image to display
    Mat img_display;
    img.copyTo( img_display );

        /// Create the result matrix
    int result_cols =  img.cols - templ.cols + 1;
    int result_rows = img.rows - templ.rows + 1;

    result.create( result_cols, result_rows, CV_32FC1 );

        /// Do the Matching and Normalize
    matchTemplate( img, templ, result, match_method );
    normalize( result, result, 0, 1, NORM_MINMAX, -1, Mat() );

        /// Localizing the best match with minMaxLoc
    double minVal; double maxVal; Point minLoc; Point maxLoc;
    Point matchLoc;

    minMaxLoc( result, &minVal, &maxVal, &minLoc, &maxLoc, Mat() );

        /// For SQDIFF and SQDIFF_NORMED, the best matches are lower values. For all the other methods, the higher the better
    if( match_method  == CV_TM_SQDIFF || match_method == CV_TM_SQDIFF_NORMED )
        { matchLoc = minLoc; }
    else
        { matchLoc = maxLoc; }

        /// Show me what you got
    rectangle( img_display, matchLoc, Point( matchLoc.x + templ.cols , matchLoc.y + templ.rows ), Scalar::all(0), 2, 8, 0 );
    rectangle( result, matchLoc, Point( matchLoc.x + templ.cols , matchLoc.y + templ.rows ), Scalar::all(0), 2, 8, 0 );

        //[1]  imshow( image_window, img_display );  
        //[1] imshow( result_window, result );       

    return img_display; //[3] add return value
}

现在,你viewController需要调用这个方法:

UIImage* matchedImage = 
       [CVWrapper templateMatchImage:self.imageView.image
                               patch:self.patchView.image
                              method:0];

看不到c ++.

3 /模板匹配实时摄像机视图

简短的回答:matchTemplate在现场摄像机环境中不能很好地工作.该算法在图像中寻找具有与贴片相同的比例和方向的匹配:它将贴片平铺在图像上以原始方向和大小滑动,以比较最佳匹配.如果图像是透视歪斜,不同尺寸或旋转到不同方向,则不会产生很好的效果.

您可以改为使用OpenCV的特征检测算法,其中一些算法已被移至非自由算法.这是一个很好的描述SIFT给你的想法.对于视频拍摄也可能想看看cap_ios.h在opencv2/highgui:这里是一个教程.