Gradle Build失败错误:包javax.servlet不存在

Question

我是gradle和构建系统的新手,我正在尝试使用gradle构建项目,但它找不到我在项目的几个类中使用的Tomcat服务器包.

我的构建配置:

apply plugin: 'java'
apply plugin: 'war'

repositories {
   flatDir { dirs "WebContent/WEB-INF/lib" }
   mavenCentral()
}

dependencies {
    compile group: 'com.orientechnologies', name: 'orient-commons', version: '1.3.0'
    compile group: 'com.orientechnologies', name: 'orientdb-client', version: '1.3.0'
    compile group: 'com.orientechnologies', name: 'orientdb-core', version: '1.3.0'
    compile group: 'com.orientechnologies', name: 'orientdb-graphdb', version: '1.3.0'
    compile group: 'com.orientechnologies', name: 'orientdb-enterprise', version: '1.3.0'
    compile group: 'com.tinkerpop.blueprints', name: 'blueprints-core', version: '2.3.0'
    compile group: 'com.tinkerpop.blueprints', name: 'blueprints-orient-graph', version: '2.3.0'
    compile group: 'com.tinkerpop', name: 'pipes', version: '2.3.0'
    compile group: 'com.tinkerpop.gremlin', name: 'gremlin-java', version: '2.3.0'
    compile group: 'com.tinkerpop.gremlin', name: 'gremlin-groovy', version: '2.3.0'

    testCompile group: 'junit', name: 'junit', version: '4.+'
    testCompile group: 'org.mockito', name: 'mockito-all', version: '1.9.5'

}
sourceSets {
    main {
        java {
            srcDir 'src'
        }
    }
    test {
        java {
            srcDir 'test'
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.3'
}
war {
    from 'WebContent'
}

当我启动Gradle Task - Build时出现错误:

OrientDBFilter.java:6: error: package javax.servlet does not exist
import javax.servlet.FilterChain;
OrientDBFilter.java:5: error: package javax.servlet does not exist
import javax.servlet.Filter;

....

Answer 1

通常你会用providedCompile.就像是:

providedCompile group: 'javax.servlet', name: 'javax.servlet-api', version: '3.0.1'

然后你的应用程序将编译,但gradle将不包括最终war文件中的servlet api.