使用TXMLDocument创建XML文档的问题

Question

我是delphi的新手,现在我必须阅读创建一个xml.我的代码如下:

function foo.createXMLDocument(): TXMLDocument;
var
  res: TXMLDocument;
  rootNode: IXMLNode;
  sl : TStringList;
begin
  res := TXMLDocument.Create(nil);
  res.Active := true;
  rootNode := res.AddChild('label');
  // create string for debug purposes
  sl := TStringList.Create;
  sl.Assign(res.XML);// sl is empty after this assignment
  //add more elements
  generateDOM(rootNode);

  Result := res;
end;

问题是,子节点数增加但res.XML为空.更不用说generateDOM过程中的其余元素似乎没有做任何事情.在你的帮助下,我将非常高兴.

Answer 1

免责声明:使用D2007测试.

您的代码确实创建了XML(<label/>),如此修改函数所示:

function createXMLDocument(): TXMLDocument;
var
  res: TXMLDocument;
  rootNode: IXMLNode;
  sl : TStringList;
begin
  res := TXMLDocument.Create(nil);
  res.Active := true;
  rootNode := res.AddChild('label');
  // create string for debug purposes
  sl := TStringList.Create; // not needed
  sl.Assign(res.XML);  // Not true: sl is empty after this assignment
  ShowMessage(sl.text);// sl is NOT empty!
  sl.Free;             // don't forget to free it! use try..finally.. to guarantee it!
  //add more elements
//  generateDOM(rootNode);
  Result := res;
end;

但它需要大量的评论:
- 您不需要本地res变量,只需使用Result.
- 您不需要额外的StringList来查看XML:Result.Xml.Text
- 如果您创建了一个,请不要忘记释放 sl StringList.
- 您返回的XmlDocument在函数外部无法使用,如果您尝试,则会提供AV.

为什么？
这是因为XMLDocument旨在用作具有所有者的Component,或者用作接口,以便管理其生命周期.
使用接口来保存rootNode的事实导致它在CreateXmlDocument函数的末尾被销毁.如果你查看代码TXMLNode._Release,你会看到它触发了TXMLDocument._Release哪些调用Destroy,除非有XMLDocument的所有者(或者一个持有对它的引用的接口).
这就是为什么XMLDocument在CreateXMLDocument函数内有效并填充,但在它之外不可用,除非您返回一个接口或提供一个所有者.

请参阅以下备用解决方案:

function createXMLDocumentWithOwner(AOwner: TComponent): TXMLDocument;
var
  rootNode: IXMLNode;
begin
  Assert(AOwner <> nil, 'createXMLDocumentWithOwner cannot accept a nil Owner');
  Result := TXMLDocument.Create(AOwner);
  Result.Active := True;
  rootNode := Result.AddChild('label');
  OutputDebugString(PChar(Result.Xml.Text));
  //add more elements
//  generateDOM(rootNode);
end;

function createXMLDocumentInterface(): IXMLDocument;
var
  rootNode: IXMLNode;
begin
  Result := TXMLDocument.Create(nil);
  Result.Active := True;
  rootNode := Result.AddChild('label');
  OutputDebugString(PChar(Result.Xml.Text));
  //add more elements
//  generateDOM(rootNode);
end;


procedure TForm7.Button1Click(Sender: TObject);
var
  doc: TXmlDocument;
  doc2: IXMLDocument;
begin
  ReportMemoryLeaksOnShutdown := True;

  doc := createXMLDocument;
  // ShowMessage( doc.XML.Text ); // cannot use it => AV !!!!
  // already freed, cannot call doc.Free;

  doc := createXMLDocumentWithOwner(self);
  ShowMessage( doc.XML.Text );

  doc2 := createXMLDocumentInterface;
  ShowMessage( doc2.XML.Text );
end;