在Coldfusion Server上实现monkehTweets

Question

我继承了一个运行Coldfusion的网站,我正在尝试在网站上获取Twitter提要.我找到了一个似乎可以完成这项工作的工具,我已经在Twitter上注册了我的应用程序,并且我有我的客户端和OAuth代码.

问题是我对Coldfusion不太熟悉,无法确切地知道我需要在页面上放置哪些代码来拉取推文.这是我正在使用的库:https://github.com/coldfumonkeh/monkehTweets

根据我的收集,我的代码看起来像这样:

<cfinvoke 
 component = "component_name" 
 method="method_name" 
 returnvariable="return_variable">
 <cfinvokeargument name="arg1" value="value">
 <cfinvokeargument name="arg2" value="value">
</cfinvoke>

不幸的是,我不知道在这些领域中应该放什么.似乎没有任何参数的列表或者您应该在名称,方法和变量字段中放置什么.我只需要提取最近的三条推文.这可能不是这里问题的标准格式,但是非常感谢知道Coldfusion的人的任何帮助.谢谢!

Answer 1

我编写了一个非常基本的演示,用于从经过身份验证的用户的时间线中提取和显示信息.

你需要从对象实例化开始,看起来你已经完成了:(显然在这里将你自己的OAuth/Twitter细节添加到init方法)

<cfset objmonkehTweet   =   new monkehTweet.com.coldfumonkeh.monkehTweet(
            consumerKey     =   '',
            consumerSecret      =   '',
            oauthToken      =   '',
            oauthTokenSecret    =   '',
            userAccountName     =   '',
            parseResults        =   true
        ) />

将parseResults值设置为true会将响应转换为可以在ColdFusion中转储并轻松读取值的结构或XML对象.

接下来,调用getUserTimeline()方法.如果我们没有将任何用户ID或屏幕名称值传递给方法调用,它将访问经过身份验证的用户的时间轴:

<cfset arrStatus = objMonkehTweet.getUserTimeline() />

由于没有以格式发送参数,monkehTweet将返回默认响应为JSON(将parseResults设置为true,将导致结构数组).

现在我们可以开始创建循环了.这是非常基本的,但可以帮助您启动和运行.

定义要返回的最大推文数:

<cfset totalTweets = 3 />

然后检查数组的长度是谨慎的(以防万一我们的结果数量少于所需的最大数量):

<cfif arrayLen(arrStatus) LT totalTweets>
    <cfset totalTweets = arrayLen(arrStatus) />
</cfif>

现在定义一个循环,从1开始,最大值为totalTweet值:

<cfoutput>
<ul>
<cfloop from="1" to="#totalTweets#" index="tweet">

    <cfset status = objMonkehTweet.entify(arrStatus[tweet]) />      
    <li>#arrStatus[tweet]['user']['name']#: #status#</li>

</cfloop>
</ul>

您现在可以像这样访问每个特定的推文:arrStatus [tweet].monkehTweet对象包含一个名为entify的辅助函数,它将任何URL,用户提及和主题标记转换为HTML URL以供显示.只需传入tweet对象,它就会返回格式化状态.您也可以直接引用响应中的任何对象,就像我们在这里使用用户名值一样.

要查看返回的内容,最好转储整个响应,以便您可以在显示中查看可以访问和使用的内容:

<cfdump var="#arrStatus#" />

我希望这有助于您的运行.