如何在vim中更改当前缓冲区或窗格的背景颜色？

Question

想象一下,我正在编码,我有不同的分割窗格.当我从一个缓冲区/窗格切换到另一个缓冲区/窗格时,我应该将哪些设置传递到vimrc以更改背景颜色？

我试过了:

autocmd BufEnter * highlight Normal ctermbg=black                                                                                                                                                                                                                              
autocmd BufLeave * highlight Normal ctermbg=white 

我想补充一点,我确信我已经启用了256种颜色

Answer 1

其实,有是一种方式来获得这种效果.请参阅@blueyed对此相关问题的回答:vim - dim inactive split pane .他提供了下面的脚本,当放在我的.vimrc中时,它会使非活动窗口的背景变暗.实际上,它使背景与为颜色列指定的颜色相同(垂直线指示所需的文本宽度).

" Dim inactive windows using 'colorcolumn' setting
" This tends to slow down redrawing, but is very useful.
" Based on https://groups.google.com/d/msg/vim_use/IJU-Vk-QLJE/xz4hjPjCRBUJ
" XXX: this will only work with lines containing text (i.e. not '~')
" from 
if exists('+colorcolumn')
  function! s:DimInactiveWindows()
    for i in range(1, tabpagewinnr(tabpagenr(), '$'))
      let l:range = ""
      if i != winnr()
        if &wrap
         " HACK: when wrapping lines is enabled, we use the maximum number
         " of columns getting highlighted. This might get calculated by
         " looking for the longest visible line and using a multiple of
         " winwidth().
         let l:width=256 " max
        else
         let l:width=winwidth(i)
        endif
        let l:range = join(range(1, l:width), ',')
      endif
      call setwinvar(i, '&colorcolumn', l:range)
    endfor
  endfunction
  augroup DimInactiveWindows
    au!
    au WinEnter * call s:DimInactiveWindows()
    au WinEnter * set cursorline
    au WinLeave * set nocursorline
  augroup END
endif

Answer 2

对于 Neovim 用户来说，有一个winhighlight选项。帮助文件提供了以下示例：

示例：为非当前窗口显示不同的颜色：

set winhighlight=Normal:MyNormal,NormalNC:MyNormalNC