Fortran中的OpenMP和共享变量,不共享

Question

我遇到了OpenMP和共享变量的问题我无法理解.我所做的一切都在Fortran 90/95中.

这是我的问题:我的main程序中定义了一个并行区域,带有子句DEFAULT(SHARED),我在其中调用了一个执行某些计算的子程序.我有一个我分配的局部变量(数组),我在其上进行计算.我期待这个数组被共享(因为该DEFAULT(SHARED)子句),但似乎并非如此.

这是我正在尝试做的一个例子,它重现了我得到的错误:

program main
  !$ use OMP_LIB
  implicit none

  integer, parameter :: nx=10, ny=10
  real(8), dimension(:,:), allocatable :: array

  !$OMP PARALLEL DEFAULT(SHARED)
  !$OMP SINGLE
  allocate(array(nx,ny))
  !$OMP END SINGLE

  !$OMP WORKSHARE
  array = 1.
  !$OMP END WORKSHARE

  call compute(array,nx,ny)

  !$OMP SINGLE
  deallocate(array)
  !$OMP END SINGLE
  !$OMP END PARALLEL

contains
  !=============================================================================
  ! SUBROUTINES
  !=============================================================================
  subroutine compute(array, nx, ny)
    !$ use OMP_LIB
    implicit none

    real(8), dimension(nx,ny) :: array
    integer :: nx, ny
    real(8), dimension(:,:), allocatable :: q
    integer :: i, j

    !$OMP SINGLE
    allocate(q(nx,ny))
    !$OMP END SINGLE

    !$OMP WORKSHARE
    q = 0.
    !$OMP END WORKSHARE

    print*, 'q before: ', q(1,1)

    !$OMP DO SCHEDULE(RUNTIME)
    do j = 1, ny
       do i = 1, nx
          if(mod(i,j).eq.0) then
             q(i,j) = array(i,j)*2.
          else
             q(i,j) = array(i,j)*0.5
          endif
       end do
    end do
    !$OMP END DO

    print*, 'q after: ', q(1,1)

    !$OMP SINGLE
    deallocate(q)
    !$OMP END SINGLE

  end subroutine compute
  !=============================================================================
end program main

当我这样执行它时,我得到一个分段错误,因为本地数组q是在一个线程上分配而在其他线程上没有,当其他线程尝试在内存中访问它时,它会崩溃.

如果我摆脱了SINGLE区域,q就会分配本地数组(虽然有时它会崩溃,这是有道理的,如果不同的线程尝试分配它,而事实就是如此(实际上它让我感到困惑,为什么它不会每次都崩溃)但是然后它显然好像数组q是私有的(因此一个线程返回我预期的值,而其他线程返回给我其他东西).

q尽管我用该子句声明了我的并行区域,但为什么数组不被共享真的让我很困惑DEFAULT(SHARED).因为我处于一个孤立的子程序中,所以我不能明确地声明q为共享,因为只有在子程序中才能知道compute...到目前为止,我仍然遇到这个问题,我找不到解决方法.

这是正常的吗？我应该期待这种行为吗？有解决方法吗？我想念一些明显的东西吗？

任何帮助将非常感谢!

Answer 1

q就OpenMP而言,是一个"在一个区域内但不在一个构造内"的实体.q本地的子例程位于并行构造期间调用的过程中,但q它本身不会出现在PARALLEL和END PARALLEL指令之间.

然后,OpenMP中此类实体的数据共享规则规定q是私有的.

诸如DEFAULT(SHARED)之类的数据共享子句仅适用于构造本身中出现的事物(词法上出现在PARALLEL和END PARALLEL之间的事物).(它们通常不适用于该地区的事物 - 该地区调用的程序可能已经单独编译,可能在任何并行结构之外调用.)