按值Hash of Hashes Perl排序

Question

假设我有哈希数据结构的哈希构造如下:

%HoH => (
     flintstones => {
               family_members    => "fred;wilma;pebbles;dino",
               number_of_members => 4,
     },
     jetsons => {
               family_members    => "george;jane;elroy",
               number_of_members => 3,
     },
     simpsons => {
               family_members    => "homer;marge;bart;lisa;maggie",
               number_of_members => 5,
     },

)

如何根据number_of_members从最大到最小的值对键(本例中的族)进行排序？然后我想打印出最高的两个.这是一个大致的想法,但我知道这是错的:

foreach $value (
    sort {
    $HoH{$a}{$number_of_members} cmp $HoH{$b}{$number_of_members}
    } keys %HoH)
my $count = 0;
while ($key, $value) = each %HoH) {
    if (count <= 2){
        print "${HoH}{$key}\t$key{$value}";
    }
}
continue {
    $count++;
};

我想要打印代码(空格是制表符分隔):

simpsons    homer;marge;bart;lisa;maggie
flintstones    fred;wilma;pebbles;dino

Answer 1

你走在正确的轨道上.您可以在哈希中使用$a和$b内部变量,并以数字方式比较值(<=>不是cmp).

打印时,我发现最简单的方法是将密钥存储在一个数组中并使用数组切片来访问它们.

use strict;
use warnings;

my %HoH = (
     flintstones => {
               family_members    => "fred;wilma;pebbles;dino",
               number_of_members => 4,
     },
     jetsons => {
               family_members    => "george;jane;elroy",
               number_of_members => 3,
     },
     simpsons => {
               family_members    => "homer;marge;bart;lisa;maggie",
               number_of_members => 5,
     },    
);
my @sorted = sort { $HoH{$b}{'number_of_members'} <=> 
                    $HoH{$a}{'number_of_members'} } keys %HoH;

for (@sorted[0,1]) {   # print only first two
    print join("\t", $_, $HoH{$_}{'family_members'}), "\n";
}

输出:

simpsons        homer;marge;bart;lisa;maggie
flintstones     fred;wilma;pebbles;dino