在均匀强度图像中检测物体

Question

我在泥中有Tiger Pugmark(足迹印象)的图像.我想检测pugmark的边界,但是图像在前景的强度上是均匀的,并且基于强度变化无法区分背景.我能做些什么来区分pugmark和背景.

老虎的pugmark http://imageshack.us/a/img407/4636/p1060993g.jpg

Answer 1

在分段任务中,如果两者都有

1. 好标记; 和
2. 感兴趣对象周围的强边缘

然后通过分水岭变换直接解决.当然,问题是获得这些标记,以及根据需要增强相关边缘.获得这些可能涉及特定问题的知识,而我没有解决您的问题.

然而,有一些通用方法可能有用.例如,来自数学形态学的连通运算符用作合并和扩展平坦区域的方式.因此,也许它可以为我们提供相对较好的问题标记.在下图中,在原始图像的灰度版本(左图像)中执行通过打开(一种连接的操作符)的形态重建,并且在右侧示出剩余的区域最大值.

现在,我们可以获得上面左图的形态梯度.我们还可以在右上图中使用小圆盘进行孔填充和扩张,以获得更平滑的轮廓 - 这定义了我们的标记图像.然后,使用我们的标记图像在渐变图像中应用分水岭变换,然后展开(侵蚀或扩张,取决于您如何看待它)分水岭线,我们得到以下图像:

我怀疑你可以轻易丢弃太大和太小的区域.然后,如果你有一些粗糙的预期尺寸的爪子,以及手掌,你可以丢弃不相关的区域.此时,只需扩展区域以形成单个组件并在原始图像中显示生成的轮廓:

执行每个步骤的示例代码(相关步骤也在评论的Matlab代码中显示):

f = Import["http://imageshack.us/a/img407/4636/p1060993g.jpg"]
g = ColorConvert[f, "Grayscale"]                           (* g = rgb2gray(f); *)
(* First image shown: *)
geo = GeodesicOpening[g, DiskMatrix[5]]  (* geo = imreconstruct(imerode(g, ... *)
                                         (*         strel('disk', 6)), g);     *)
(* Second image shown: *)
marker = MaxDetect[geo]                        (* marker = imregionalmax(geo); *)

(* Watershed on gradient with markers. *)
mgrad = ImageSubtract[Dilation[geo, 1], Erosion[geo, 1]]; (* mgrad = ...       *)
          (* imdilate(geo,strel('square',3)) - imerode(geo,strel('square',3)); *)
ws = Image[           (* ws = watershed(imimposemin(mgrad, bwmorph(imfill(...  *)
 WatershedComponents[mgrad,      (* imregionalmax(geo),'holes'),'dilate'))));  *)
  Dilation[FillingTransform[marker], DiskMatrix[1]]]]

(* Third image shown: *)
wsthick = Erosion[ws // ImageAdjust, DiskMatrix[5]]

(* Connected component selection based on some supposed sizes. *)
ccs = SelectComponents[wsthick, "Count", 1000 < # < 3000 || 6000 < # < 10000 &]

(* Final image (thick border on binarized filled dilated ccs) *)
res = ImageAdd[f, Dilation[MorphologicalPerimeter[FillingTransform[
     MorphologicalPerimeter[Dilation[ccs, DiskMatrix[9]]]]], 2]]