有没有办法从Oracle中的PL/SQL刷新输出？

Question

我有一个从shell脚本中调用的SQL脚本,需要很长时间才能运行.它目前包含dbms_output.put_line各个方面的陈述.这些打印语句的输出显示在日志文件中,但仅在脚本完成后才显示.

有没有办法确保在脚本运行时输出显示在日志文件中？

Answer 1

并不是的.DBMS_OUTPUT的工作方式是:您的PL/SQL块在数据库服务器上执行而不与客户端交互.因此,当您调用PUT_LINE时,它只是将该文本放入服务器内存中的缓冲区中.当你的PL/SQL块完成时,控制权返回给客户端(在这种情况下我假设是SQLPlus); 此时,客户端通过调用GET_LINE从缓冲区中获取文本,并显示它.

因此,更频繁地使输出显示在日志文件中的唯一方法是将大型PL/SQL块拆分为多个较小的块,以便更频繁地将控制权返回给客户端.根据您的代码所做的事情,这可能不实用.

其他替代方法是使用UTL_FILE写入文本文件,可以随时刷新,或使用自治事务过程将调试语句插入数据库表并在每个文件表后提交.

Answer 2

两种选择:

1. 您可以使用自治事务在日志记录表中插入日志记录详细信息.您可以在另一个SQLPLUS/Toad/sql开发人员等会话中查询此日志记录表.您必须使用自治事务才能在不干扰主sql脚本中的事务处理的情况下提交日志记录.

2. 另一种方法是使用管道函数返回您的日志记录信息.请参阅此处以获取示例:http://berxblog.blogspot.com/2009/01/pipelined-function-vs-dbmsoutput.html使用流水线功能时,您不必使用其他SQLPLUS/Toad/sql开发人员等......会议

Answer 3

如果可能，应使用自己的函数替换对dbms_output.put_line的调用。

这是此功能的代码WRITE_LOG -如果您希望能够在两种日志记录解决方案之间进行选择：

将日志写入自主事务中的表

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/

或直接写入托管数据库的数据库服务器

这使用Oracle目录 TMP_DIR

CREATE OR REPLACE PROCEDURE to_dbg_file(p_fname varchar2, p_log varchar2)
  -- file mode: 
  -- requires
--- CREATE OR REPLACE DIRECTORY TMP_DIR as '/directory/where/oracle/can/write/on/DB_server/';
AS
  l_file utl_file.file_type;
BEGIN
  l_file := utl_file.fopen('TMP_DIR', p_fname, 'A');
  utl_file.put_line(l_file, p_log);
  utl_file.fflush(l_file);
  utl_file.fclose(l_file);
END to_dbg_file;
/

WRITE_LOG

然后WRITE_LOG，可以在两种用途之间切换的过程或可以取消激活该过程以避免性能损失（g_DEBUG:=FALSE）。

CREATE OR REPLACE PROCEDURE write_log(p_log varchar2) AS
  -- g_DEBUG can be set as a package variable defaulted to FALSE
  -- then change it when debugging is required
  g_DEBUG boolean := true;
  -- the log file name can be set with several methods...
  g_logfname varchar2(32767) := 'my_output.log';
  -- choose between 2 logging solutions:
  -- file mode: 
  g_TYPE varchar2(7):= 'file';
  -- table mode: 
  --g_TYPE varchar2(7):= 'table';
  -----------------------------------------------------------------
BEGIN
  if g_DEBUG then
    if g_TYPE='file' then
      to_dbg_file(g_logfname, p_log);
    elsif g_TYPE='table' then
      to_dbg_table(p_log);
    end if;
  end if;  
END write_log;
/

这是如何测试以上内容：

1）从您的SQLPLUS 启动此（文件模式）：

BEGIN
  write_log('this is a test');
  for i in 1..100 loop
    DBMS_LOCK.sleep(1);
    write_log('iter=' || i);
  end loop;
  write_log('test complete');
END;
/

2）在数据库服务器上，打开一个shell并

CREATE OR REPLACE PROCEDURE to_dbg_table(p_log varchar2)
  -- table mode: 
  -- requires
  -- CREATE TABLE dbg (u varchar2(200)   --- username
  --                 , d timestamp       --- date
  --                 , l varchar2(4000)  --- log 
  -- );
AS
   pragma autonomous_transaction;
BEGIN
  insert into dbg(u, d, l) values (user, sysdate, p_log);
  commit;
END to_dbg_table;
/