将MDI表单显示为模态

Question

这听起来与MDI的性质背道而驰。我有时需要将MDI表单（FormStyle = fsMdiChild）显示为模态。而且我还需要访问另一个MDI表单的Application.CreateForm和OnShow事件之间的部分，即

Application.CreateForm(Form2,TForm2); // but don't set form2's visible property true.
Form2.caption:='not working example'; 
Form2.SomeMagicToSetVisibleTrue;

有任何想法吗？

Answer 1

对于第一个问题：添加另一个构造函数，例如CreateAsMDI，如下所示：

constructor TModalAndMDIForm.CreateAsMDI(AOwner: TComponent); 
begin 
  f_blChild := true; 
  GlobalNameSpace.BeginWrite; 
  try 
    inherited CreateNew(AOwner); 
    if(not(csDesigning in ComponentState)) then begin 
      Include(FFormState, fsCreating); 
      try 
        FormStyle := fsMDIChild; 
        if(not(InitInheritedComponent(self, TForm))) then 
          raise Exception.CreateFmt('Can't create %s as MDI child', [ClassName]); 
      finally 
        Exclude(FFormState, fsCreating); 
      end; 
    end; 
  finally 
    GlobalNameSpace.EndWrite; 
  end; 
end; 

在普通的构造函数中，只需将变量f_blChild设置为false并调用继承的create。

您还需要两件事，而不是自我解释：

procedure TModalAndMDIForm.Loaded; 
begin 
  inherited; 
  if(f_blChild) then 
    Position := poDefault 
  else begin 
    Position := poOwnerFormCenter; 
    BorderStyle := bsDialog; 
  end; 
end; 
//----------------------------------------------------------------------------- 
procedure TModalAndMDIForm.DoClose(var Action: TCloseAction); 
begin 
  if(f_blChild) then 
    Action := caFree; 
  inherited DoClose(Action); 
end; 

现在，如果使用标准构造函数创建，则可以将其称为模式模态，如果使用CreateAsMDI创建，则可以将其称为MDI子级。

如果您在表单的声明中包含此内容

property IsChild: boolean read f_blChild; 

您甚至可以根据表单是否为MDI子项来执行操作，只需查询isChild属性即可。

至于第二个问题：不要使用Application.CreateForm，而是自己创建表单：

这是模态和MDI的两个创建：

//Modal 
frmDialog := TMyForm.Create(self); 
// Your Code
frmDialog.ShowModal; 
frmDialog.Release; 

//MDI-Child 
frmDialog := TMyForm.CreateChild(self); 
// Your code
frmDialog.Show;

我已经在DelphiPraxis网站上的一篇文章中翻译了此答案。