使用grails标准api定义OR条件

Question

我有以下域对象:

class User {
    String name
    Transaction transaction

    static constraints = {
        transaction nullable: true
    }
}

class Transaction {        
    boolean successful
    User user        
    static belongsTo = User
}

我想选择所有users没有成功交易的东西.这意味着我希望没有任何transaction(transaction == null)的用户和具有成功值false(transaction.successful == false)的事务的用户.我想使用Criteria API执行此操作(因为这可以与基于用户输入的其他条件结合使用).

我试过这个:

def c = User.createCriteria()
def results = c {
    or {
        isNull 'transaction'
        transaction {
            eq 'successful', false
        }
    }
}

但是,这只给了我有交易的用户(成功的价值false).但我没有得到交易所在的用户null

以下代码显示了我如何创建一些示例数据:

def createUserAndTransaction(String name, Boolean successful = null) {
    User u = new User(name: name)
    if (successful != null) {
        Transaction t = new Transaction(user: u, successful: successful)
        u.setTransaction(t)
    }
    u.save()
}

def init = { servletContext ->
    createUserAndTransaction 'john', true
    createUserAndTransaction 'mike', false
    createUserAndTransaction 'pablo'
}

我的条件查询仅mike在这种情况下返回.但我想mike和pablo.我错过了什么？

Answer 1

所以问题是它默认为内连接.您必须为表创建别名并定义其连接类型:

createAlias("transaction", "t", CriteriaSpecification.LEFT_JOIN)

or {
    isNull("t")
    eq("t.successful", false)
}