如何在Delphi中获取文件的创建/最后修改日期？

Question

我想将这些属性的文件作为整数值.

Answer 1

尝试

function FileAge(const FileName: string; out FileDateTime: TDateTime): Boolean;

来自SysUtils.

Answer 2

Delphians倾向于喜欢FindFirst方法(SearchRec结构中有一些),但我建议使用Win32 API函数GetFileAttributesEx.

Answer 3

来自DSiWin32免费软件库:

function DSiFileTimeToDateTime(fileTime: TFileTime; var dateTime: TDateTime): boolean;
var
  sysTime: TSystemTime;
begin
  Result := FileTimeToSystemTime(fileTime, sysTime);
  if Result then
    dateTime := SystemTimeToDateTime(sysTime);
end; { DSiFileTimeToDateTime }

function  DSiGetFileTimes(const fileName: string; var creationTime, lastAccessTime,
  lastModificationTime: TDateTime): boolean; 
var
  fileHandle            : cardinal;
  fsCreationTime        : TFileTime;
  fsLastAccessTime      : TFileTime;
  fsLastModificationTime: TFileTime;
begin
  Result := false;
  fileHandle := CreateFile(PChar(fileName), GENERIC_READ, FILE_SHARE_READ, nil,
    OPEN_EXISTING, 0, 0);
  if fileHandle <> INVALID_HANDLE_VALUE then try
    Result :=
      GetFileTime(fileHandle, @fsCreationTime, @fsLastAccessTime,
         @fsLastModificationTime) and
      DSiFileTimeToDateTime(fsCreationTime, creationTime) and
      DSiFileTimeToDateTime(fsLastAccessTime, lastAccessTime) and
      DSiFileTimeToDateTime(fsLastModificationTime, lastModificationTime);
  finally
    CloseHandle(fileHandle);
  end;
end; { DSiGetFileTimes }

Answer 4

function GetFileModDate(filename : string) : TDateTime;
var
   F : TSearchRec;
begin
   FindFirst(filename,faAnyFile,F);
   Result := F.TimeStamp;
   //if you really wanted an Int, change the return type and use this line:
   //Result := F.Time;
   FindClose(F);
end;

F.Time 已被弃用，帮助文件显示使用 F.TimeStamp。
只是为了更新这个由于 Delphi 的更高版本

Answer 5

System.IOUtils 确实有一个 TFile 记录，其中包含多个用于获取文件年龄的函数，例如 GetCreationTime、GetLastAccessTime、GetLastWriteTime