Google电子表格查询:如何替换列标题中的文本？

Question

=QUERY(B2:C9; "select (C * 100 / B) - 100")我的Google云端硬盘电子表格中有这样的查询.

显示为列标题的是difference(quotient(product(100.0()))100.0()).

我想在那里放一个人类可读的描述.

我怎样才能做到这一点？

Answer 1

=QUERY(B2:C9;"select (C*100/B)-100 label (C*100/B)-100 'Value'")

https://developers.google.com/chart/interactive/docs/querylanguage#Label

Answer 2

如果您想要重命名多个列，则可以使用一个LABEL关键字，然后使用逗号分隔字段及其新名称分配。

"select B, D, D*C where D <> 0 label D 'Staff', D*C 'Cost'"

Answer 3

请记住，那里有一个技巧。

查询的工作示例：

"SELECT C, COUNT(C), AVG(G), AVG(E) GROUP BY C ORDER BY COUNT(C) DESC LABEL COUNT(C) 'My count' FORMAT AVG(G) '##0.00', AVG(E) '##0.00'"

不工作的查询示例：

"SELECT C, COUNT(C) LABEL COUNT(C) 'My count', AVG(G), AVG(E) GROUP BY C ORDER BY COUNT(C) DESC FORMAT AVG(G) '##0.00', AVG(E) '##0.00'"

也没有工作例如查询：

"SELECT C, COUNT(C), AVG(G), AVG(E) GROUP BY C ORDER BY COUNT(C) DESC FORMAT AVG(G) '##0.00', AVG(E) '##0.00' LABEL COUNT(C) 'My count'"

仅当它与其他命令以正确的顺序放置时才有效。

Answer 4

这是违反直觉的，但您必须定义重新标记的列TWICE；一次在“SQL”字符串中，然后将该label子句附加到 SQL 字符串的末尾。

所以，如果你想选择 A、B、C 并且“B”被标记为“Foo”，你可以这样做：

=QUERY(B2:C9;"select A, B, C   label B 'Foo' ")

如果您在进行计算，请注意准确匹配 SQL 字符串定义和标签定义。例如：

=QUERY(B2:C9;"select A, B*2, C   label B*2 'Foo' ")

https://developers.google.com/chart/interactive/docs/querylanguage#Label