使用CMake用/ MT而不是/ MD编译

Question

使用CMake用/ MT而不是/ MD编译

Jos*_*osh 48 cmake

我在Windows SDK和NMake Makefiles上使用CMake.

默认情况下,它使用/MD编译器开关进行编译.

如何更改它以使用/MT开关编译？

Answer 1

Fra*_*ser 68

您可以修改CMAKE_CXX_FLAGS_<Build Type>和/或CMAKE_C_FLAGS_<Build Type>变量:

set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

Run Code Online (Sandbox Code Playgroud)

如果您的CMake标志已经包含/MD,您可以确保在插入点之后执行上述命令/MD(稍后添加/MT覆盖冲突的现有选项),或者您可以从头开始设置标志:

set(CMAKE_CXX_FLAGS_RELEASE "/MT")
set(CMAKE_CXX_FLAGS_DEBUG "/MTd")

Run Code Online (Sandbox Code Playgroud)

,或者也可以取代现有的/MD和/MDd与价值观/MT,并/MTd通过执行类似分别为:

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        )
foreach(CompilerFlag ${CompilerFlags})
  string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
endforeach()

Run Code Online (Sandbox Code Playgroud)

这个请求很常见 - 奇怪的是CMake仍然没有宏或设置来支持这种开箱即用.我最终在几乎所有项目中都这样做 - 尤其是那些具有外部依赖性的项目,例如GoogleMock,它们对编译器ABI有自己的默认观点 (23认同)
@Fraser可以通过运行`cmake -D CMAKE_CXX_FLAGS =“/ MT”..`从命令行设置此选项吗？ (2认同)

Answer 2

Com*_*sMS 12

CMake最终在3.15版中使用MSVC_RUNTIME_LIBRARYtarget属性添加了对此的适当支持：

cmake_minimum_required(VERSION 3.15)
cmake_policy(SET CMP0091 NEW)
project(my_project)

add_executable(foo foo.c)
set_property(TARGET foo PROPERTY
             MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

Run Code Online (Sandbox Code Playgroud)

您也可以通过设置CMAKE_MSVC_RUNTIME_LIBRARY变量来指定全局默认值。

@VladimirGamalyan 与策略一样，如果您的“cmake_minimum_required”足够新，则无需显式请求新行为。我主要将策略包含在答案中，以便人们知道此功能存在策略，并在他们关心兼容性影响时查找它。 (5认同)
这应该是公认的解决方案，至少对于现代 cmake 来说是这样。这比黑客攻击 CMAKE_CXX_FLAGS 不那么不透明...... (3认同)
在 3.16.3 上，它可以在没有“cmake_policy(SET CMP0091 NEW)”的情况下以某种方式工作，这真的是必需的吗？ (2认同)
@DavidKarla 除了这个答案是在最初的问题提出六年后给出的，更不用说提出这个问题的人自 2015 年以来就没有登录过。 (2认同)
这是行不通的。 (2认同)

Answer 3

Car*_*aro 8

看来，对于Visual Studio的2017年15和CMake的3.12的方式来代替/MD由/MT是加入该片段到的CMakeLists.txt文件：

if(MSVC)
    add_compile_options(
        $<$<CONFIG:>:/MT> #---------|
        $<$<CONFIG:Debug>:/MTd> #---|-- Statically link the runtime libraries
        $<$<CONFIG:Release>:/MT> #--|
    )
endif()

Run Code Online (Sandbox Code Playgroud)

我在官方 CMake 存储库中找到了这个解决方案：https : //gitlab.kitware.com/cmake/cmake/issues/18390

注意：此块应添加在`add_executable`或`add_library`之前 (4认同)

归档时间：	13 年前
查看次数：	32475 次
最近记录：	6 年，7 月前