在Android Studio中将commons-io依赖项添加到gradle项目

Question

非常简单的问题 - 如何在gradle Android项目中添加commons-io依赖项？

我尝试了以下内容

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.5.+'
    }
}

apply plugin: 'android'

dependencies {
    compile files('libs/android-support-v4.jar')
    compile group: 'commons-io', name: 'commons-io', version: '2.0.1'
}

但它不起作用错误是

Gradle:配置项目':LearnIt'时出现问题.

无法通知项目评估监听器.无法解析配置':LearnIt:_DebugCompile'的所有依赖项. >找不到commons-io:commons-io:2.0.1. 要求:learnit:LearnIt:未指定

Answer 1

截至目前(2014年5月),如果您使用默认生成的项目,它实际上非常简单(虽然很难找到说明!

打开第二级 build.gradle,并将以下行添加到dependencies {:

compile "commons-io:commons-io:+"

这将获得最新版本commons-io.我的完整文件如下所示:

apply plugin: 'android'

android {
    compileSdkVersion 19
    buildToolsVersion "19.0.0"

    defaultConfig {
        minSdkVersion 18
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
    buildTypes {
        release {
            runProguard false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
        }
    }
}

dependencies {
    compile "commons-io:commons-io:+"
}

Answer 2

你需要声明一个存储库,你要从中解析commons-io库(例如MavenCentral):

buildscript {
    repositories {
        mavenCentral()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:0.5.+'
    }
}

apply plugin: 'android'

repositories{
    mavenCentral()
}

dependencies {
    compile files('libs/android-support-v4.jar')

    compile group: 'commons-io', name: 'commons-io', version: '2.0.1'
}    

Answer 3

使用gradlePlease获取依赖项.

将以下内容添加到app/build.gradle文件中:

dependencies {
    compile 'org.apache.commons:commons-io:1.3.2'
}

// 更新

implementation group: 'commons-io', name: 'commons-io', version: '2.6'

Answer 4

使用 gradle 更新 2020

// Home Page : https://commons.apache.org/

// IO - https://commons.apache.org/proper/commons-io/
implementation group: 'commons-io', name: 'commons-io', version: '2.7'

// String / Text 
implementation group: 'org.apache.commons', name: 'commons-text', version: '1.8'