我通过软件安装策略部署了 Flash Player。如何升级？

Question

我有一台 Windows Server 2008 机器作为我的 DC。今年早些时候，我创建了一个软件安装 GPO 来部署 Adob​​e Flash Player 插件 MSI。我将策略分配给计算机，大约一半运行 Windows XP x86，另一半运行 Windows 7 x64。这一切都像发条一样。

在创建软件安装策略时，我通过在 Orca 中编辑 MSI 禁用了 Flash Player 插件的自动更新功能。我这样做是因为我希望我的所有机器都运行完全相同版本的插件。

现在，一段时间过去了，较新版本的 Flash Player 插件已经发布。是时候推出插件的更新版本了。我已经有了新的 MSI，但我不知道下一步该做什么。

• 我在软件安装 GPO 中看到了升级选项卡，但那里读取的所有内容都将用于更大主程序的附加组件，而不是随时间发布的更新。
• 我读过最好使用新的 MSI 创建新的软件安装策略，撤销旧的 GPO，并分配新的 GPO。我觉得，随着时间的推移，我最终会收到比有效政策更多的撤销政策。
• 我还读到，有些人通过用新的 MSI 替换旧的 MSI 并简单地告诉 GPO 重新部署而取得了成功。这似乎是一种后门方法，只会让我陷入困境。

简而言之，通过组策略推出新版本的正确、最佳实践或首选方式是什么？

Answer 1

我已经用 Flash Player（和其他软件）做过很多次了。你想要做的是：

• 使用 ORCA 以您想要的任何自定义进行编辑，并将其另存为转换（或将其另存为全新的 MSI，任何适合您的方式）。

• 将新的 MSI（和转换）放在您的软件部署共享上。

• 将此软件（和转换）添加到您现有的策略中。它会自动将其检测为对以前版本的 Flash Player 的升级。如果这是您之前配置它的方式（x86：插件和 ActiveX，x64：插件和 ActiveX），您可以在同一策略中添加所有版本，或者您可以继续使用您已有的任何 GPO 布局。只需确保您在政策中添加同类产品，它就会自动将这些检测为升级。

• 如果出于某种原因，它们没有被自动检测为升级，您可以在策略中自行设置。这是处理这种情况的正确方法。

这真的没什么特别的。

您应该考虑的一件事是，不是每次有新版本时都使用 ORCA 编辑 MSI，您可以使用 Flash Player 首选项创建此处概述的 mms.cfg 文件。该文件在升级过程中不会被触及，因此您只需要推出一次该文件，然后您就可以部署一个普通的 Flash Player 安装。我已经使用具有项目级别目标的组策略文件首选项将其放在混合环境中 x86 和 x64 机器上的正确位置。

Answer 2

我相信升级是这样做的最佳实践方法。我过去曾广泛使用过这种方法，没有出现任何问题。

添加新的 MSI 作为组策略对象中的另一个包，选择高级部署方法。它应该被检测为对先前部署的 Flash Player 的升级。如果不是，您可以手动将其添加到更新选项卡。

Answer 3

我有可怕与一些V9，V10的看似随机的故障数（见我在这个答案的结论注），和V11的Adobe Flash MSI的不卸载或升级不当，而使PC上的MSI数据库的状态这让我很警惕。我最终求助于使用启动脚本：

• 检查HKEY_LOCAL_MACHINE\SOFTWARE\Macromedia\FlashPlayer\CurrentVersion注册表值以查看当前安装的版本是否是最新的（WOW6432NODE如有必要，将 a 添加到该路径中）并在版本是最新的情况下保释

• 使用旧的、不受支持的、现在几乎不可能的msizap.exe实用程序从“过去”中删除已知失败的 MSI（包括 {2BD2FA21-B51D-4F01-94A7-AC16737B2163}、{B7B3E9B3-FB14-4927-894B- E9124509AF5A} 和 {FA1D6742-0515-4A94-AD5D-F0484026E4A2}）。

• 使用 Adob​​e 提供的卸载程序 EXE 以静默方式删除任何当前版本的 Flash

• 使用当前 Adob​​e 提供的 EXE 安装程序和-install activex参数（我只在大多数站点中安装 ActiveX 控件）来安装当前版本

• 写出一个'mms.cfg。文件以防止自动升级

这是我的启动脚本的清理版本。如果您想这样做，您需要出去并获取适当的 EXE。

@echo off
SET MSIZAP=\\my.domain.com\netlogon\bin\msizap.exe
SET DFSPATH=\\my.domain.com\dfsroot\Packages\Adobe

SET UNINSTALL=%DFSPATH%\uninstall_flash_player_x86.exe
SET INSTALL=%DFSPATH%\install_flash_player_11.4.402.278_active_x.exe 

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET WOW6432NODE=WOW6432NODE\

SET VER_FLAG_KEY=HKEY_LOCAL_MACHINE\SOFTWARE\%WOW6432NODE%Macromedia\FlashPlayer
SET VER_FLAG_VALUE=11,4,402,278

REG QUERY "%VER_FLAG_KEY%" /v CurrentVersion | find /i "%VER_FLAG_VALUE%" > NUL 2>NUL
if errorlevel 1 goto do_install
goto :EOF

:do_install
rem Uninstall all old versions of Flash.
start /wait /min "" "%UNINSTALL%" -uninstall activex

rem MSIZAP all old versions
start /wait /min "" "%MSIZAP%" TW! {2BD2FA21-B51D-4F01-94A7-AC16737B2163}
start /wait /min "" "%MSIZAP%" TW! {B7B3E9B3-FB14-4927-894B-E9124509AF5A}
start /wait /min "" "%MSIZAP%" TW! {FA1D6742-0515-4A94-AD5D-F0484026E4A2}

rem Run new installer
start /wait /min "" "%INSTALL%" -install activex

rem Block future automatic updates
SET DEST="%windir%\system32\Macromed\Flash\mms.cfg"

rem Detect 64-bit Windows
IF NOT "%ProgramFiles(x86)%"=="" SET DEST="%windir%\SysWOW64\Macromed\Flash\mms.cfg"

rem I'm using "sort" here because the redirect is being interpreted as "1>" and
rem doing "1 >" causes a space to be stored in the file, which "breaks" the file.
echo AutoUpdateDisable=1|sort>%DEST%

我在卸载旧的 Flash MSI 时遇到的问题主要是：

• “Adobe Flash Player 11 ActiveX -- 错误 1714。无法删除旧版本的 Adob​​e Flash Player 11 ActiveX。请联系您的技术支持组。系统错误 1612。”

• “错误 2753：文件 'installax.exe' 未标记为安装”

对我来说，压垮骆驼的最后一根稻草是看到这些错误在拥有 1,000 多台客户端 PC 的客户站点中随机发生。我需要确保 Flash 更新正在发生，并且随机卸载 MSI 失败不是一种选择。MSI 故障发生在每次后续启动时，这会减慢启动过程，这只会雪上加霜。

我还没有详细查看 v11 MSI。v9 和 v10 MSI 只不过是使用命令行参数执行基于 EXE 的 Flash 安装程序的自定义操作。我对 MSI 的质量没有留下深刻印象，因为使用 Windows Installer 来运行基于 EXE 的安装程序并不是使用Windows Installer。