如何在 Windows 上自动找到损坏的符号链接？

Question

不确定这是否是一种糟糕的风格，但我在这里问这个问题是因为我在其他地方找不到答案，然后我自己制定了一个解决方案。我很想看看其他人的解决方案，但几天后我会发布我自己的解决方案。

在我的特定情况下，我在 Windows 7 上运行，但我对其他/旧版本 Windows 的答案感兴趣。我意识到一个答案是“安装一个版本的 Unix find，然后像 Unix 一样解决”，但我想要一个更“本机”的解决方案。

编辑 2012-07-17：澄清：“自动”我的意思是我可以作为脚本的一部分运行的东西，而不是一个 GUI 工具，只需按一下按钮就可以完成所有工作，因为我想做这无人看管。

Answer 1

有点迟了，但这是我自己对我的问题的回答。它与 Unix 上通常的方法基本相同：找到所有链接，然后对损坏的链接进行操作；只是不那么简洁。下面的脚本在转储有关它们的一些信息后删除损坏的符号链接。

@echo off

rem Grab the list of directories to scan, before we "pushd to dir containing this script",
rem so that we can have the default be "dir from which we ran this script".
setlocal
if x%CD%==x (echo Command Extensions must be enabled. && goto :eof)
set ORIGINAL_DIR=%CD%

pushd %~dp0

set DIRS_TO_CHECK=%*
if x%DIRS_TO_CHECK%==x (
    set DIRS_TO_CHECK=.
)

rem Find all the files which are both links (/al) and directories (/ad).
rem (We use "delims=" in case any paths have a space; space is a delim by default.)
rem If not, delete it (and assume something else will fix it later :-).
echo Deleting broken symlinks ...
echo.
for %%D in (%ORIGINAL_DIR%\%DIRS_TO_CHECK%) do (
    echo Checking %%D
    echo.
    pushd %%D
    if errorlevel 1 (
        echo Cannot find "%%D"
        echo.
        goto :Next_Dir
    )
    rem Clean up broken directory links.
    for /f "usebackq delims=" %%L in (`dir /adl /b`) do (
        rem Check the directory link works.
        rem Redirecting to nul just to hide "The system cannot find the file specified." message.
        pushd "%%L" >nul 2>&1
        if errorlevel 1 (
            echo Deleting broken directory symlink "%%L".
            rem First dump out some info on the link, before we delete it.
            rem I'd rather a more human-readable form, but don't know how to get that.
            fsutil reparsepoint query "%%L"
            rmdir "%%L"
            echo.
        ) else (
            popd
        )
    )
    rem Clean up broken file (non-directory) links.
    for /f "usebackq delims=" %%L in (`dir /a-dl /b`) do (
        rem Check the file link works.
        rem Redirecting to nul just to hide "The system cannot find the file specified." message.
        copy "%%L" nul >nul 2>&1
        if errorlevel 1 (
            echo Deleting broken file symlink "%%L".
            rem First dump out some info on the link, before we delete it.
            rem I'd rather a more human-readable form, but don't know how to get that.
            fsutil reparsepoint query "%%L"
            rm "%%L"
            echo.
        ) else (
            popd
        )
    )
    popd
    :Next_Dir
    rem Putting a label on the line immediately before a ')' causes a batch file parse error, hence this comment.
)
echo Deleting broken symlinks ... done.

:Finally
popd