从 xp 中的批处理脚本中删除临时文件

Question

我正在寻找一个好的批处理脚本，它可以从 Windows（尽可能多的变体）机器（例如 Windows 临时文件夹、所有用户 IE 临时文件夹等）中快速找到并清理所有已知的安全临时文件夹/文件。我喜欢像 CCleaner（通过 Cleanmgr.exe）这样的 UI 工具，但是当我尝试快速和/或很少参与清理多台计算机时，有一个脚本会很好。

加上脚本，我可以将多个脚本链接在一起。也许一个然后启动各种防病毒和/或恶意软件检测器。

任何人都有一个好的或可以指向一个好的资源？

Answer 1

这是我写的一个小脚本，我保存在我的 USB 实用程序驱动器上......非常适合 citrix 服务器:)

@echo off
Echo Started %time%
Echo Started %time% >> temps.txt
Echo Running for XP... >> temps.txt
Echo Running for XP...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temp\" (
    RMDIR /S /Q "%%G\Local Settings\Temp"
    MKDIR "%%G\Local Settings\Temp"
    Echo Cleared %%G\Local Settings\Temp
    Echo Cleared %%G\Local Settings\Temp >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\Local Settings\Temporary Internet Files\" (
    RMDIR /S /Q "%%G\Local Settings\Temporary Internet Files\"
    MKDIR "%%G\Local Settings\Temporary Internet Files\"
    Echo Cleared %%G\Local Settings\Temporary Internet Files\
    Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Running for Vista >> temps.txt
Echo Running for Vista...
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Temp\" (
    RMDIR /S /Q "%%G\AppData\Local\Temp\"
    MKDIR "%%G\AppData\Local\Temp\"
    Echo Cleared %%G\AppData\Local\Temp\
    Echo Cleared %%G\AppData\Local\Temp\ >> temps.txt
)
FOR /F "tokens=*" %%G IN ('DIR /B /AD') DO IF EXIST "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\" (
    RMDIR /S /Q "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
    MKDIR "%%G\AppData\Local\Microsoft\Windows\Temporary Internet Files\"
    Echo Cleared %%G\Local Settings\Temporary Internet Files\
    Echo Cleared %%G\Local Settings\Temporary Internet Files\ >> temps.txt
)
Echo Done.
Echo Ended %time%
Echo Ended %time% >> temps.txt

使用风险自负，等等......这会删除东西。

我从文档和设置文件夹或 Vista 上的用户运行它。您可以轻松地将 CD 命令放在最上面，以便从您想要的任何地方运行它。

cd %userprofile%
cd ..

此外，根据我的经验，随时清除临时文件夹通常是安全的。使用 temp 中的文件的程序将锁定它们，并且此脚本将在该文件上出错并继续运行。

IF EXIST 行在这里特别好，它可以防止脚本在 NetworkService 和类似文件夹中创建文件夹，如果您不是在 Vista 或 XP 上运行它，该部分运行速度非常快。

在运行脚本的地方创建 temps.txt 日志文件

编辑：##windows-server 在 Freenode 上的建议： 问：你为什么不在开始时检测它正在运行的操作系统并运行适当的部分？A：我经常在离线媒体上使用这个脚本，比如解压出来的硬盘。