SQL Server 中的 ODBC 连接锁定表

Question

SQL Server 中的 ODBC 连接锁定表

Sab*_*bre 5 ms-access sql-server odbc sql-server-2008-r2 locking

我们的 ERP 系统比现代系统稍差，后端目前安装在 SQL Server 2008 R2 上。我们通过管理授权（并非总是如此）允许许多用户随意从该系统中提取数据以将数据处理为他们喜欢的报告风格（BI、Powerquery、Access），这是完全不切实际的做法。、Excel 等）

尽管所有这些报告生成用户都只有选择权限，但还有一些其他应用程序能够实际操作数据，以执行 EDI、自动数据输入等操作。

从逻辑上讲，这会在表上创建许多竞争条件。先到先得，或者更糟的是，仍在提供服务，请稍等，或者只是不......我相信这进一步导致了多年来无法解释的数据损坏需要供应商协助纠正。因为并非所有应用程序都经过正确编码以预测其他事物可能会中断其自己的私有意图的可能性。

因此，任务是在我最近才继承的系统上尽可能证明/纠正/减轻它。

我的第一直觉告诉我，如果没有不同供应商产品之间的某种 IPC/错误/事务控制以及他们修复它的意愿、控制源代码或限制它的能力，这是无法完成的，这不能从 DBA 修复从角度来看，这只是导致应该预期的潜在有害副作用的不良做法。

所以此时我所能做的就是证明这一点，看看如果有证据，我可以在坚持必须这样做的管理层心中征求某种行为改变。

第一步，我正在运行一个连续的分析器输出到磁盘，尽管资源密集，但我必须能够返回并查看已提交的内容，由谁提交，以及它产生了什么影响。我还使用 perfmon 日志记录和 PAL 来尝试交叉引用服务器上的密集行为，“当处理器和内存挂钩时，SQL 服务器在该实例中做了什么（很可能是为编写的 GUI 之一提供服务，性能不佳，十个表连接，非索引查询，一些报告编写者/工具扔在一起”

其中一种情况刚刚发生，我们在 ERP 系统中有一个用户无法执行某项功能，我们发现该用户登录的数据库没有使用 ERP 软件（使用 ODBC，SQL 用户只能选择访问，以及MS Access），让他们断开连接并完成该功能。管理层拒绝相信它们是相关的，因为它们“应该处理不同的表，而用户只有选择访问权限”，而且我没有发生之前瞬间的个人资料历史记录。

所以，这一切归结为一个问题，DBA学员在那里，给的任务验算该应用程序A被应用B的不利影响，你有什么建议给报价？

Answer 1

Sti*_*ing 1

不幸的是，我们在我工作的地方处理过太多与此相关的问题。如果出现问题，不懂数据库的人会在 MS Access 中“实时”打开 SQL 表。起初，事情可能会显得短暂，因为它们可能会快速打开和关闭 Access。但有时他们会在出去吃午饭或度过长周末时让实时 SQL 表上的 MS Access 打开，从而阻止尝试使用数据库的应用程序。简单地说，阻塞会对任何尝试使用被阻塞的 SQL 行、表或数据库的应用程序产生不利影响。

为了证明一切，我们真正要做的就是捕获数据以sp_who2找到区块链。

话虽这么说，当我离开控制台时，我仍然使用十多年前编写的以下代码（我的意思是我仍在使用 DBCC InputBuffer）来查找这些讨厌的问题 - 如果需要的话（请在测试/开发环境，看看它是否满足您的需求）。虽然肯定不是惯例中的劳斯莱斯，但它仍然对我有用。

此代码本质上是在新数据库 DBADMIN 中创建一个表 BlockingProcesses 来存储阻塞信息。两个存储过程sp__Maint_BlockWatch一起sp__Maint_Blockingprocesses工作来查找阻止程序。SQL 作业每分钟运行一次以检查块。您可能需要更改下面代码中的一些小事情，例如需要执行作业的用户、可能的调度等。

CREATE DATABASE DBADMIN
GO

USE [dbadmin]
GO

SET ANSI_NULLS ON
GO   
SET QUOTED_IDENTIFIER ON
GO    
SET ANSI_PADDING ON
GO

CREATE TABLE [dbo].[BlockingProcesses]
(
    [PK] [int] IDENTITY(1,1) NOT NULL,
    [last_batch] [datetime] NULL,
    [spid] [int] NULL,
    [BlockedTotal] [int] NULL,
    [LoginName] [varchar](128) NULL,
    [DBName] [varchar](128) NULL,
    [HostName] [varchar](128) NULL,
    [Program_Name] [varchar](255) NULL,
    [CPU] [bigint] NULL,
    [Physical_IO] [bigint] NULL,
    [Memusage] [bigint] NULL,
    [Open_tran] [int] NULL,
    [EventInfo] [varchar](max) NULL,
    [InsertTime] [smalldatetime] NULL,
    [Params] [varchar](500) NULL
) ON [PRIMARY] TEXTIMAGE_ON [PRIMARY]    
GO

SET ANSI_PADDING OFF
GO

ALTER TABLE [dbo].[BlockingProcesses] 
   ADD DEFAULT (getdate()) FOR [InsertTime]
GO

USE [master]
GO

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER OFF
GO

CREATE PROCEDURE [dbo].[sp__Maint_BlockWatch]
AS
    declare @blocker smallint

    DECLARE blocker_cursor CURSOR FOR 
         select distinct blocked 
         from sysprocesses 
         where blocked != 0

    OPEN blocker_cursor
    FETCH NEXT FROM blocker_cursor INTO @blocker

    WHILE (@@fetch_status <> -1)
    BEGIN
      IF (@@fetch_status = -2)
      BEGIN
  FETCH NEXT FROM blocker_cursor INTO @blocker
           CONTINUE
      END

  exec sp__Maint_Blockingprocesses @blocker

 FETCH NEXT FROM blocker_cursor INTO @blocker
    END
DEALLOCATE blocker_cursor


GO

USE [master]
GO

/****** Object:  StoredProcedure [dbo].[sp__Maint_BlockingProcesses]    Script Date: 09/20/2016 13:31:03 ******/
SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO



CREATE procedure [dbo].[sp__Maint_BlockingProcesses]
@spid smallint
as
declare
@blockedTotal int, 
@loginame varchar(128), 
@dbid int,
@hostname varchar(128),
@program_name varchar(128),
@cpu bigint,
@physical_io bigint,
@memusage bigint,
@open_tran int,
@dbname varchar(128),
@EventInfo varchar(255),
@Last_batch datetime
create table #temp
(
 EventType varchar(50),
 Parameters int,
 EventInfo varchar(255)
)

insert into #temp
exec ('dbcc inputbuffer('+@spid+')')

select @EventInfo=eventinfo from #temp
select @blockedTotal= count(*) from sysprocesses where blocked = @spid
select @loginame=loginame, @dbid=dbid, @hostname=hostname, @program_name=program_name, @cpu=cpu,
@physical_io = physical_io, @memusage=[memusage], @open_tran=open_tran, @Last_batch=last_batch
from sysprocesses where spid=@spid
select @dbname = name from sysdatabases where dbid=@dbid
insert into dbadmin..blockingprocesses(last_batch,spid, BlockedTotal, LoginName, DBName, HostName, Program_Name, CPU, Physical_IO, Memusage, Open_tran, EventInfo)
values(@last_batch, @spid, @BlockedTotal, @LogiName, @DBName, @HostName, @Program_Name, @CPU, @Physical_IO, @Memusage, @Open_tran, @EventInfo)
drop table #temp



GO



USE [msdb]
GO

/****** Object:  Job [_Monitor Blocks]    Script Date: 09/20/2016 13:29:34 ******/
BEGIN TRANSACTION

DECLARE @ReturnCode INT
SELECT @ReturnCode = 0
/****** Object:  JobCategory [[Uncategorized (Local)]]]    Script Date: 09/20/2016 13:29:34 ******/
IF NOT EXISTS (SELECT name FROM msdb.dbo.syscategories WHERE name=N'[Uncategorized (Local)]' AND category_class=1)
BEGIN
EXEC @ReturnCode = msdb.dbo.sp_add_category @class=N'JOB', @type=N'LOCAL', @name=N'[Uncategorized (Local)]'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback

END

DECLARE @jobId BINARY(16)
EXEC @ReturnCode =  msdb.dbo.sp_add_job @job_name=N'_Monitor Blocks', 
        @enabled=1, 
        @notify_level_eventlog=2, 
        @notify_level_email=0, 
        @notify_level_netsend=0, 
        @notify_level_page=0, 
        @delete_level=0, 
        @description=N'No description available.', 
        @category_name=N'[Uncategorized (Local)]', 
        @owner_login_name=N'sa', @job_id = @jobId OUTPUT
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
/****** Object:  Step [Look For Blocking]    Script Date: 09/20/2016 13:29:34 ******/
EXEC @ReturnCode = msdb.dbo.sp_add_jobstep @job_id=@jobId, @step_name=N'Look For Blocking', 
        @step_id=1, 
        @cmdexec_success_code=0, 
        @on_success_action=1, 
        @on_success_step_id=0, 
        @on_fail_action=2, 
        @on_fail_step_id=0, 
        @retry_attempts=0, 
        @retry_interval=1, 
        @os_run_priority=0, @subsystem=N'TSQL', 
        @command=N'exec sp__Maint_BlockWatch', 
        @database_name=N'master', 
        @flags=0
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_update_job @job_id = @jobId, @start_step_id = 1
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobschedule @job_id=@jobId, @name=N'Run Once a Minute', 
        @enabled=1, 
        @freq_type=4, 
        @freq_interval=1, 
        @freq_subday_type=4, 
        @freq_subday_interval=1, 
        @freq_relative_interval=0, 
        @freq_recurrence_factor=0, 
        @active_start_date=20060918, 
        @active_end_date=99991231, 
        @active_start_time=0, 
        @active_end_time=235959
        --, @schedule_uid=N'bf518f11-c5ba-438a-8afd-e4e33e8dad1e'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
EXEC @ReturnCode = msdb.dbo.sp_add_jobserver @job_id = @jobId, @server_name = N'(local)'
IF (@@ERROR <> 0 OR @ReturnCode <> 0) GOTO QuitWithRollback
COMMIT TRANSACTION
GOTO EndSave
QuitWithRollback:
    IF (@@TRANCOUNT > 0) ROLLBACK TRANSACTION
EndSave:

GO

Run Code Online (Sandbox Code Playgroud)

归档时间：	9 年，2 月前
查看次数：	5468 次
最近记录：	8 年，8 月前